mIRC Scripting  


Geri dön   mIRC Scripting > mIRC Scripting > Help - Yardım

Help - Yardım mIRC Scripting hakkında her konuda yardım alabileceğiniz bölümdür.

Like Tree1Teşekkür
  • 1 Post By Feragat
Cevapla
 
LinkBack Seçenekler
  #1  
Alt 27 Kasım 2013, 22:19
Avatar Yok

mS Puan: 1
mS Derece: Beer
 
Üyelik tarihi: 21 Şubat 2012
Mesajlar: 2
Konular: 1
Eklentiler: 0
Alınan Teşekkür: 0
Yapılan Teşekkür: 0
Standart Puan sistemi

Selam söyle bir kod yapma sansımız var mı
Bir puan sistemi ama puan sistemini belirlediğimiz nickler verecek
Mesela
puan ekleyecek veya ceza ekleyecek nickleri eklemek icin

!pnick ekle nick ve !pnick sil nick komutunu kullanabilecek nick veya nickler.. Bir nevi founder sop misali
!pnick ekle nick : puan ve ceza ekleyebilecek nick'i ekleme
!pnick sil nick : puan ve ceza ekleyebilecek seviyedeki nick'i silme
!cezaekle nick puan : nick'e eklenen ceza puanı
!puanekle nick puan : nick'e eklenen artı puan
!puanlar : bütün puan tablosu
!puan nick : sadece bir puan eklenen + veya - puan nick üzerinden gösterimi.

Benzer bir kod var ama belirlenen nickler değilde herkes puan ekleyebiliyor. O kodu paylasayım size.

Kod:
on *:text:*:#:{
  if $1 == !cezaekle {
    if (!$2) { msg # Nick belirtiniz. | return }
    if (!$3) { msg # Ceza Puan'ı belirtiniz. | return }
    if (!$hget(Ceza)) { .hmake Ceza | .hload -i Ceza Ceza.mercy }
    .hdec -m Ceza $2 $3 | .hload -i Ceza Ceza.mercy
    msg # Nick:[ $2 ] Ceza Puan'ı Toplam:[ $hget(Ceza,$2) ]
    if $hget(Ceza,$2) == 50 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 60 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 70 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 80 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 90 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 100 { msg # Puanın $hget(Ceza,$2) oldu }
  }
  if $1 == !puanekle {
    if (!$2) { msg # Nick belirtiniz. | return }
    if (!$3) { msg # Puan belirtiniz. | return }
    if (!$hget(Ceza)) { .hmake Ceza | .hload -i Ceza Ceza.mercy }
    .hinc -m Ceza $2 $3 | .hload -i Ceza Ceza.mercy
    msg # Nick:[ $2 ] Toplam Puan'ı:[ $hget(Ceza,$2) ]
    if $hget(Ceza,$2) == 50 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 60 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 70 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 80 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 90 { msg # Puanın $hget(Ceza,$2) oldu }
    if $hget(Ceza,$2) == 100 { msg # Puanın $hget(Ceza,$2) oldu }
  }
  if $1 == !puanlar { 
    var %c1 = 1,%c2 = $hget(Ceza,0).item
    while %c1 <= %c2 { msg # Nick: $hget(Ceza,%c1).item Puanı: $hget(Ceza,$hget(Ceza,%c1).item) | inc %c1 }
  }
  if $1 == !puan {
    if (!$2) { msg # Nick belirtiniz. | return }
    if !$strip($2) || $strip($2) == $nick {
      if $hget(Ceza,$2) { msg # 4 :[ $nick ] 1kullanıcısına ait toplam ; [ $hget(Ceza,$2) ] Puan bulunmakta | return }
      else { msg #  :[ $nick ]  nin Puan'ı bulunmamaktadır. | return }
    }
    if $strip($2) {
      if $hget(Ceza,$2) { msg #  :[ $strip($2) ] kullanıcısına ait toplam ; [ $hget(Ceza,$2) ]1 Puan bulunmakta | return }
      else { msg #  :[ $strip($2) ]  Puan'ı bulunmamaktadır. | return }
    }
  }

Konu Toprak tarafından (01 Aralık 2013 Saat 11:19 ) değiştirilmiştir.
Alıntı ile Cevapla
Sponsored Links
  #2  
Alt 28 Kasım 2013, 01:28
Feragat - ait Kullanıcı Resmi (Avatar)
 Headcoder 

mS Puan: 801
mS Derece: Feragat ÇalışkanFeragat ÇalışkanFeragat ÇalışkanFeragat ÇalışkanFeragat ÇalışkanFeragat ÇalışkanFeragat Çalışkan
 
Üyelik tarihi: 31 Mart 2012
Bulunduğu yer: $mircdir
Mesajlar: 89
Konular: 41
Eklentiler: 5
Alınan Teşekkür: 61
Yapılan Teşekkür: 37
Standart

Kullanımı:
!puanekle Nick puan : Belirtilen Nicke Puan ekler.
!cezaekle Nick puan : Belirtilen Nicke Ceza Puanı ekler.
!puan Nick : Tek bir nick ve puanını listeler.
!puanlar : Nickleri ve puanlarını listeler
!nicksil Nick : Listeden puanı ile beraber siler

Bu komutları kullanacak kişileri ekleyebilmek için:
!pnick ekle Nick : Yektili nick ekleme
!pnick sil Nick : Yetkili nick silme
!plist : yetkili listesi
Not: < !pnick ekle Nick - !pnick sil Nick - !plist > komutlarını kullanabilecek nickleri kodun şu kısmından ayarlayın;
Kod:
alias -l ynt return Beer|Feragat|Nick3
Aralarına | işareti koyarak örnekteki gibi çoğaltabilirsiniz.

Önemli Not: Kodun hangi Kanalda/Kanallarda çalışmasını istiyorsan koyu belirttiğim satıra kanalın ismini yaz;
Kod:
{ return #kanal }
Eğer bir den fazla kanalda kullanacaksan
Kod:
{ return #kanal,#kanal1,#kanal2 }
şeklinde örnekte ki gibi aralarına virgül koyarak çoğaltabilirsin.

Aslında hash table ile de yapılabilir. Bazı komutları pekiştirmek adına hash table kullanmadım. Zaten senin paylaştığın ve sanırım Toprak ın yazdığı kodda hash table kullanılmıştı.

Kodu eklerken, sağlıklı çalışması için boş bir remote sayfasına eklemeni öneririm. (Eklediğin mIRC üzerinde /knl yaparak kullanım komutlarınıda görebilirsin.) İyi forumlar.


Kod:
alias -l ek { if !$isid { %admin = $addtok(%admin,$1,32) } } 
alias -l sl { if !$isid { %admin = $remtok(%admin,$1,32) } } 

alias knl { 
  if $isid { return #kanal }
  else { echo -a Kullanım Komutları: 1-) Yetkililer için: <!pnick ekle Nick> <!pnick sil Nick> <!plist> 
    echo -a  2-) Yetkilendirilmiş kullanıcılar için: <!puanekle Nick Puan> <!cezaekle Nick Puan> <!puan Nick> <!puanlar> <!nicksil Nick> 
  } 
}

alias -l ynt return Beer|Feragat|Nick3

on $*:text:/^[.!]pnick\s+ekle\s+\S+$/Si:$($knl): { 
  if $regex($nick,/^( $+ $ynt $+ )$/i) { 
    if $findtok(%admin,$3,32) { msg $chan $3 Nicki zaten listede ekli! } 
    else { ek $3 | msg $chan $3 Nicki yetkili listesine eklendi. } 
  }
  else { msg $chan Bu komutu kullanmaya yetkili değilsin! } 
}

on $*:text:/^[.!]pnick\s+sil\s+\S+$/Si:$($knl): {
  if $regex($nick,/^( $+ $ynt $+ )$/i) { 
    if $findtok(%admin,$3,32) { sl $3 | msg $chan $3 Nicki listeden silindi. }
    else { msg $chan $3 Nicki zaten ekli değil! } 
  }
  else { msg $chan Bu komutu kullanmaya yetkili değilsin! }
}

on $*:text:/^[.!]plist$/Si:$($knl): { 
   if $regex($nick,/^( $+ $ynt $+ )$/i) { 
    if !%admin { msg $chan Yetkili listesi boş! }
    else { msg $chan Yetkililer: %admin } 
  }
  else { msg $chan Bu komutu kullanmaya yetkili değilsin! }
}

on $*:text:/^[.!]cezaekle\s+\S+\s+\d+$/Si:$($knl): { 
  if $findtok(%admin,$nick,32) { writeini -n cezalar.ini $2 Puan: $calc($readini(cezalar.ini,$2,Puan:) - $3) 
    msg $chan $2 Nickine $3 Ceza puanı eklendi. | msg $chan $2 Nickinin Toplam Puanı: $readini(cezalar.ini,$2,Puan:) 
  }
  else { msg $chan Bu komutu kullanmak için yetkili değilsin! }
} 

on $*:text:/^[.!]puanekle\s+\S+\s+\d+$/Si:$($knl): { 
  if $findtok(%admin,$nick,32) { writeini -n cezalar.ini $2 Puan: $calc($readini(cezalar.ini,$2,Puan:) + $3) 
    msg $chan $2 Nickine $3 Puan eklendi. | msg $chan $2 Nickinin Toplam Puanı: $readini(cezalar.ini,$2,Puan:) 
  }
  else { msg $chan Bu komutu kullanmak için yetkili değilsin! }
}

on $*:text:/^[.!]puan\s+\S+$/Si:$($knl): { 
  if $findtok(%admin,$nick,32) { 
    if !$lines(cezalar.ini) { msg $chan Liste Boş! }
    else {
      if !$readini(cezalar.ini,$2,Puan:) { msg $chan $2 Nicki listede yok! } 
      else { msg $chan Nick: $ini(cezalar.ini,$ini(cezalar.ini,$2)) Puan: $readini(cezalar.ini,$2,Puan:)  }
    }
  }
  else { msg $chan Bu komutu kullanmak için yetkili değilsin! }
}

on $*:text:/^[.!]puanlar$/Si:$($knl): {
  if $findtok(%admin,$nick,32) { 
    if !$lines(cezalar.ini) { msg $chan Liste Boş! }
    else { 
      var %a = 1,%b = $lines(cezalar.ini) 
      while %a <= %b { msg $chan Nick: $$ini(cezalar.ini,%a) Puan: $readini(cezalar.ini,$ini(cezalar.ini,%a),Puan:) | inc %a }  
    }
  }
  else { msg $chan Bu komutu kullanmak için yetkili değilsin! } 
}

on $*:text:/^[.!]nicksil\s+\S+$/Si:$($knl): { 
  if $findtok(%admin,$nick,32) { 
    if !$lines(cezalar.ini) { msg $chan Liste Boş! }
    else { 
      if !$ini(cezalar.ini,$2,0) { msg $chan $2 Nicki listede  yok! } 
      else { remini cezalar.ini $2 | msg $chan $2 Nicki ve bilgileri silindi. }
    }
    else { msg $chan Bu komutu kullanmak için yetkili değilsin! }
  }
}
¿ buna teşekkür etti.
__________________
Vi veri veniversum vivus vici..

Konu Feragat tarafından (02 Aralık 2013 Saat 19:18 ) değiştirilmiştir. Sebep: küçük bir eklenti
Alıntı ile Cevapla
  #3  
Alt 28 Kasım 2013, 20:37
Avatar Yok

mS Puan: 1
mS Derece: Beer
 
Üyelik tarihi: 21 Şubat 2012
Mesajlar: 2
Konular: 1
Eklentiler: 0
Alınan Teşekkür: 0
Yapılan Teşekkür: 0
Standart

Sağolasın feragat
Alıntı ile Cevapla
Cevapla

Etiketler
puan, sistemi

Seçenekler

Yetkileriniz
Konu Acma Yetkiniz Yok
Cevap Yazma Yetkiniz Yok
Eklenti Yükleme Yetkiniz Yok
Mesajınızı Değiştirme Yetkiniz Yok

BB code is Açık
Smileler Açık
[IMG] Kodları Açık
HTML-Kodu Kapalı
Trackbacks are Açık
Pingbacks are Açık
Refbacks are Açık


Benzer Konular
Konu Konuyu Başlatan Forum Cevaplar Son Mesaj
/* !nick ekle isim yaş - sistemi (Advanced) */ WingmaN Showcase - Hazır kodlar 0 24 Ağustos 2011 10:18
Üyelik sistemi Dicaste Help - Yardım 1 15 Ağustos 2011 15:50
SüperLig Puan sıra durumu !puandurumu SaGoPa Showcase - Hazır kodlar 1 12 Ekim 2009 16:00
Bekleyenleri Gösterir Uyarı Sistemi UnLimitedBOY Showcase - Hazır kodlar 0 10 Ekim 2009 22:05


Yasal Uyarı

    5651 sayılı yasada belirtilen "Yer Sağlayıcı" olarak hizmet sunmaktadır. İlgili yasaya göre site yönetiminin tüm içerikleri kontrol etme yükümlülüğü yoktur. Bu sebep ile sitemiz, uyarıları dikkate alarak yasa dışı paylaşımlar hakkında gerekli işlemleri yapmaktadır. Oluşabilecek yasal sorumluluklar üyelerimize aittir. Gerekli şikayet bildirimleri yapabilmek için "burayı" tıklayarak gerekli alanları doldurup yapabilirsiniz.
mIRCScripting©
Powered by vBulletin®
Copyright © 2000-2015, Jelsoft Enterprises Ltd.
SEO by vBSEO 3.6.1

1 2 13 14 16 17 18 19 21 22 23 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 49 50 51 52 54 55 56 57 58 59 60 61 62 63 67 68 69 70 71 72 73 74 75 76