mIRC Scripting  


Geri dön   mIRC Scripting > mIRC Scripting > Showcase - Hazır kodlar

Showcase - Hazır kodlar mIRC Scripting hakkında hazır kodları bulup, paylaşabileceğiniz bölüm.

Cevapla
 
LinkBack Seçenekler
  #1  
Alt 26 Şubat 2011, 19:52
Avatar Yok
 Coders 

mS Puan: 621
mS Derece: Difuzyon ÇalışkanDifuzyon ÇalışkanDifuzyon ÇalışkanDifuzyon ÇalışkanDifuzyon ÇalışkanDifuzyon Çalışkan
 
Üyelik tarihi: 16 Temmuz 2009
Bulunduğu yer: code talks!
Mesajlar: 83
Konular: 36
Eklentiler: 4
Alınan Teşekkür: 5
Yapılan Teşekkür: 0
Exclamation mIRC Ekran Koruyucu

Merhabalar,

mIRC scriptinizde boş geçen zamanlara Ekran Koruyucu atamak için derlediğim bir çalışmayı sizlerle paylaşıyorum.

mIRC scriptinizin aktif olduğu halde ($appactive, yani simge durumunda olmadığı hallerde) Idle sürenizin ($idle) belirleyeceğiniz limitin aşımında ve aynı zamanda mouse koordinatlarının sabitlenmesiyle harekete geçen bir kodlamadır.
Idle süreniz mIRC üzerinde bir kanala,özele vb. ekranlarda hareketsiz kalmanızla oluşan bir süredir,bu kısma dikkatinizi çekerim.Herhangi bir pencerede /komut girdisi girmeniz halinde $idle sürenizin sıfırlandığını hatırlatırım.

Mouse koordinatlarının belirlediğiniz $idle süresince hareketsiz kalmasınında mIRC aktif ekranında hareketsiz bulunduğunuza yorumladım.

Böylelikle mIRC Ekran Koruyucu belirlediğiniz Resim seçeneğini tam ekran olarak atayacaktır.mIRC görünümlerine örneklerle bakalım:



Dialog ile Önizleme 1



*

*

mIRC Ekran Koruyucu



*

*

*

*

Dialog ile Önizleme 2



*

mIRC Ekran Koruyucu




Dialog işlemleri:
Arka plan resim için "Gözat" kısmından jpg jpeg bmp gif ico png türü dosyalardan bir tanesini bilgisayarınızdan seçiyorsunuz.Seçtiğiniz resmi yine dialog içinde oluşturduğum Picture Window ile önizleme olarak göreceksinizdir,ki beğeniniz artık bu noktada size kalmış.Bu önizlemenin belirleyici olamasında sizlere yardımcı olacağını düşündüm.
Ardından "Idle Süresi Seçin" kısmında ne kadar süre hareketsiz kalacağınızda,ekran koruyucunun harakete geçmesini belirliyorsunuz.
"Başlat" direktifiyle ekran koruyucunuz işlem sorgusuna başlayacaktır.

mIRC Ekran Koruyucu aktif halde iken herhangi bir tuşa basmanız veya mouse kıpırdatmanız halinde mIRC Ekran Koruyucu resim penceresi kapanacaktır,mIRC ekranınıza tekrar kavuşacaksınızdır.

Aşağıdaki kodu mIRC Scriptinizin REMOTE başlığına ekledikten sonra Status veya #kanal veya Özel pencersinde sağ tıkladığınızda Ekran Koruyucu başlığını göreceksiniz.Seçmeniz halinde mIRC Ekran Koruyucu Ayarları dialogu karşınıza çıkacaktır.

Kod:
alias ekran {
  dialog $iif($dialog(picture),-v,-m) picture picture
}
dialog picture {
  title "Ekran Koruyucu Ayarları"
  size -1 -1 207 268
  option pixels
  icon 1, 2 29 200 144
  edit "Resim dosyası seçin --->", 2, 3 5 140 21, read autohs
  button "Gözat", 3, 154 5 50 20, flat
  text "Idle süresi seçin", 5, 10 185 81 15
  text "---|", 8, 164 203 15 12
  text "/", 11, 144 185 15 12
  text "\", 12, 144 222 15 12
  combo 4, 9 200 80 20, vsbar drop
  button "Başlat", 6, 99 200 51 20
  button "Durdur", 7, 153 180 51 20
  button "Çıkış", 9, 153 222 51 20
  link " Product by Difuzyon ", 10, 50 250 106 14
}

on *:dialog:picture:sclick:*:{
  if ($did == 3) { 
    %dify.picture = $shortfn($$sfile($mircdir,Resim dosyası seçin))
    if %dify.picture && $regex(%dify.picture,/\.(jpg|bmp|png|gif|ico|jpeg)$/i) { 
      did -ra $dname 2 $nopath(%dify.picture) 
      did -g $dname 1 %dify.picture
    }
  }
  if ($did == 6) && $did(4).seltext && %dify.picture { screen | echo -a 7Ekran Koruyucu aktif ! | did -b $dname 6 | did -b $dname 4 | did -e $dname 7 }  
  if ($did == 7) { .timerdify off | echo -s 10Ekran Koruyucu devre dışı ! | did -e $dname 6 | did -e $dname 4 | did -b $dname 7 }
  if ($did == 4) { set %dify.time $calc($remove($did(4).seltext,dakika) *60) }
  if ($did == 9) { $iif($window(@picture),window -c @picture) | dialog -x $dname $dname }
  if ($did == 10) { url -n http://www.ircforumlari.net/uyeler/40159.html }
}

on *:dialog:picture:close:0:window -c @picture
on *:dialog:picture:dclick:*:{
  if $did == 1 { 
    window -pdha +b @picture 1 1 $pic(%dify.picture).width $pic(%dify.picture).height
    drawpic @picture 0 0 %dify.picture
  }
}
on *:dialog:picture:init:0:{
  did -a $dname 4 1 dakika
  did -a $dname 4 3 dakika
  did -a $dname 4 5 dakika
  did -a $dname 4 10 dakika
  did -a $dname 4 15 dakika
  did -a $dname 4 30 dakika
  if %dify.time { did -kcu $dname 4 $iif(%dify.time == 60,1,$iif(%dify.time == 180,2,$iif(%dify.time == 300,3,$iif(%dify.time == 600,4,$iif(%dify.time == 900,5,$iif(%dify.time == 1800,6)))))) }
  if %dify.picture { did -ra $dname 2 $nopath(%dify.picture) | did -g $dname 1 %dify.picture }
  if $timer(dify) { did -b $dname 6 | did -b $dname 4 } | else { did -e $dname 6 | did -e $dname 4 | did -b $dname 7 }
}
Menu status,query,channel {
  Ekran Koruyucu:ekran
}
alias screen {
  .timerdify 0 1 senkronize
}
alias pict.show {
  window -padk0x +lnb @ScreenSaver 
  drawpic -sm @ScreenSaver 0 0 $window(@ScreenSaver).w $window(@ScreenSaver).h 1 1 $pic(%dify.picture).width $pic(%dify.picture).height %dify.picture
}
alias senkronize {
  hinc -mu2 dify.mouse.x $mouse.dx
  hinc -mu2 dify.mouse.y $mouse.dy
  if $idle > %dify.time && $hget(dify.mouse.x,$mouse.dx) > %dify.time && $appactive == $true && $hget(dify.mouse.y,$mouse.dy) > %dify.time {
    if $dialog(picture) { window -c @picture | dialog -x picture }
    .timerdify off
    .timerdify.show.pict -m 1 150 pict.show
  }
}
alias screenclose {
  window -c @Screensaver | screen
}
menu @Screensaver {
  mouse:{ screen.control }
  sclick:{ screen.control }
  rclick:{ screen.control }
}

alias screen.control {
  if $mouse.x != $hget(dify.mouse.x,$mouse.dx) || $mouse.y != $hget(dify.mouse.y,$mouse.dy) { 
    hfree -w dify.* | screenclose 
  }
}
on *:keydown:@Screensaver:*:screenclose
Hoşca paylaşımlar dilerim...
__________________
Koli
Alıntı ile Cevapla
Sponsored Links
Cevapla

Etiketler
ekran, koruyucu, mirc

Seçenekler

Yetkileriniz
Konu Acma Yetkiniz Yok
Cevap Yazma Yetkiniz Yok
Eklenti Yükleme Yetkiniz Yok
Mesajınızı Değiştirme Yetkiniz Yok

BB code is Açık
Smileler Açık
[IMG] Kodları Açık
HTML-Kodu Kapalı
Trackbacks are Açık
Pingbacks are Açık
Refbacks are Açık


Benzer Konular
Konu Konuyu Başlatan Forum Cevaplar Son Mesaj
100. mIRC Scripting kullanıcımız. L4roXyL Meeting - Duyurular 12 30 Mart 2019 13:48
Zurna mIRC KarabasaN Full scripts - Scriptler 3 07 Eylül 2009 15:51
mIRC Scripting X. L4roXyL Tutorials - Dersler 0 13 Temmuz 2009 22:07
mIRC Tips(balon uyarıları) L4roXyL Tutorials - Dersler 0 13 Temmuz 2009 21:58


Yasal Uyarı

    5651 sayılı yasada belirtilen "Yer Sağlayıcı" olarak hizmet sunmaktadır. İlgili yasaya göre site yönetiminin tüm içerikleri kontrol etme yükümlülüğü yoktur. Bu sebep ile sitemiz, uyarıları dikkate alarak yasa dışı paylaşımlar hakkında gerekli işlemleri yapmaktadır. Oluşabilecek yasal sorumluluklar üyelerimize aittir. Gerekli şikayet bildirimleri yapabilmek için "burayı" tıklayarak gerekli alanları doldurup yapabilirsiniz.
mIRCScripting©
Powered by vBulletin®
Copyright © 2000-2015, Jelsoft Enterprises Ltd.
SEO by vBSEO 3.6.1

1 2 13 14 16 17 18 19 21 22 23 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 49 50 51 52 54 55 56 57 58 59 60 61 62 63 67 68 69 70 71 72 73 74 75 76