mIRC Scripting  


Geri dön   mIRC Scripting > mIRC Scripting > Snippets - Parça kodlar

Snippets - Parça kodlar mIRC Scripting hakkında "parça /ufak kod" niteliği taşıyan kodlarını bulup veya paylaşabileceğiniz bölüm.

Cevapla
 
LinkBack Seçenekler
  #1  
Alt 23 Eylül 2010, 15:11
Avatar Yok
oLd oLd isimli Üye şimdilik offline konumundadır

mS Puan: 11
mS Derece: oLd
 
Üyelik tarihi: 20 Ağustos 2010
Mesajlar: 1
Konular: 1
Eklentiler: 0
Alınan Teşekkür: 0
Yapılan Teşekkür: 0
Arrow Bigtext

Kod:
alias bigtext {
  if (!$1) {
    echo -ace info * BigText: Insufficient Parameters.
    return
  }
  tokenize 9 $1-
  if ($0 == 1) { var %fc = 01, %bc = 00, %fs = 12, %ff = Tahoma }
  else {
    if ($3) { var %fc = $gettok($2,1,32), %bc = $gettok($2,2,32), %fs = $gettok($3,1,32), %ff = $gettok($3,2-,32) }
    else {
      if ($gettok($2,2-,32) isnum) { var %fc = $gettok($2,1,32), %bc = $gettok($2,2,32), %fs = 12, %ff = Tahoma }
      else { var %fs = $gettok($2,1,32), %ff = $gettok($2,2-,32), %fc = 01, %bc = 00 }
    }
  }
  if (%bc !isnum 0-15) { %bc = 00 }
  if (%fc !isnum 0-15) { %fc = 01 }
  if (!%ff || !$isfontinstalled($qt(%ff))) { %ff = Tahoma }
  if (!%fs || %fs !isnum) { %fs = 12 }
  var %text = $1, %i 0, %y 0
  %fc = $base(%fc,10,10,2)
  %bc = $base(%bc,10,10,2)
  window -hp @bigtext
  drawfill -r @bigtext $color(%bc) $color(%bc) 0 0
  drawtext -brp @bigtext $color(%fc) $color(%bc) $qt(%ff) %fs 0 0 %text
  var %heightend = $height(%text,%ff,%fs) - 1, %widthend = $width(%text,%ff,%fs,0,1) - 1
  while (%y <= %heightend) {
    var %x 0, %s = $null
    while (%x <= %widthend) {
      var %c = $iif($getdot(@bigtext,%x,%y) != $color(%bc),$coc($v1,%fc),%bc)
      if (%lc != %c) {
        var %lc = %c
        %c = $+($chr(3),%c,$chr(44),%c)
      }
      else %c = $null
      %s = $+(%s,%c,@)
      inc %x
    }
    %s = $+($chr(3),%bc,$chr(44),%bc,@,%s,$chr(3),%bc,$chr(44),%bc,@)
    if ($regex(%s,/\x03(?! $+ %bc $+ )/)) {
      .timerbig $+ %i 1 $calc(%i * 2) msg $active %s
      inc %i
    }
    inc %y
  }
  window -c @bigtext
}
alias coc {
  var %i 0
  while (%i < 16) {
    if ($color(%i) == $1) return $base(%i,10,10,2)
    inc %i
  }
  return $base($2,10,10,2)
}
;Alias by praetorian.
alias isfontinstalled {
  var %w = @isfontinstalled,%f = isfontinstalled.bmp
  window -ak0pBfh +d %w -1 -1 200 100
  drawfill -r %w $rgb(0,0,0) $rgb(0,0,0) 0 0
  drawtext -r %w $rgb(255,255,255) "this is surely not the name of an installed font" -9 5 5 test.
  drawsave %w %f
  var %crc = $crc(%f)
  clear %w
  drawfill -r %w $rgb(0,0,0) $rgb(0,0,0) 0 0
  drawtext -r %w $rgb(255,255,255) $+(",$1,") -9 5 5 test.
  drawsave %w %f
  var %crc2 = $crc(%f)
  .remove %f
  window -c %w
  if (%crc != %crc2) { return $true }
  else { return $false }
}
IRC'te buyuk yazmanizi saglayacak ufak bir kod.
*Kullanirken kisa kelimeleri kullanin, uzun kelimeleri yazdiginizda kanala agir gidebilir ve okuyamaz bir hal alir.

*Ornek; <oLd> Seni seviyorum <- degil de,
<oLd> Seni
<oLd> Seviyorum
seklinde yazin, iyi calismalar.
Alıntı ile Cevapla
Sponsored Links
Cevapla

Etiketler
bigtext

Seçenekler

Yetkileriniz
Konu Acma Yetkiniz Yok
Cevap Yazma Yetkiniz Yok
Eklenti Yükleme Yetkiniz Yok
Mesajınızı Değiştirme Yetkiniz Yok

BB code is Açık
Smileler Açık
[IMG] Kodları Açık
HTML-Kodu Kapalı
Trackbacks are Açık
Pingbacks are Açık
Refbacks are Açık



Yasal Uyarı

    5651 sayılı yasada belirtilen "Yer Sağlayıcı" olarak hizmet sunmaktadır. İlgili yasaya göre site yönetiminin tüm içerikleri kontrol etme yükümlülüğü yoktur. Bu sebep ile sitemiz, uyarıları dikkate alarak yasa dışı paylaşımlar hakkında gerekli işlemleri yapmaktadır. Oluşabilecek yasal sorumluluklar üyelerimize aittir. Gerekli şikayet bildirimleri yapabilmek için "burayı" tıklayarak gerekli alanları doldurup yapabilirsiniz.
mIRCScripting©
Powered by vBulletin®
Copyright © 2000-2015, Jelsoft Enterprises Ltd.
SEO by vBSEO 3.6.1

1 2 13 14 16 17 18 19 21 22 23 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 49 50 51 52 54 55 56 57 58 59 60 61 62 63 67 68 69 70 71 72 73 74 75 76