/* Kanala girişte, Karşılama (Advanced / Gelişmiş ) */

WingmaN · #1 24 Ağustos 2011, 10:13

/* Kullanımı */

Bot, mantığında çalışmaktadır. Yani kendi mIRC'ine eklersen eklediğin mirc üzerinden kendin komut giremezsin. Bot olarak hitab ettiğin bot mIRC'inin içerisine ekleyeceksin ve kullanacaksın.

Bot, Unreal IRCd sistemlerine göre eklenmiştir.

/* Komutlar */
Komutlar , #kontrol kanalında çalışmaktadır, komut listesi aşağıdaki gibidir.

!ekle nick mesaj : Eklenen nick'e karşılama mesajı ekler.
!sil nick : Ekli olan, kayıtlı nick'i silecektir.
!liste / !listele : Ekli olan kayıtlı nick'leri gösterir.

Not: Ekleme yaparken, mesaj kısmını " Sunucu ROOT adminlerinden osman kanala girdi. " şeklinde eklemelisin, veya kafana göre istediğin mesajı yazabilirsin, bot sadece mesajı okuyacak.

/* Muaf Bilgisi */

Kod:

 if ($regex(#,/(Help|operhelp)/i) || $regex($nick,/(muaf1|muaf2)/i)) { return }

Kod satırında bulunan yerler, muaf nick ve kanalları işaretler, " Help|operhelp " muaf kanallardır, " muaf1|muaf2 " muaf nick'lerdir.

Ekleme yapmak istiyorsan , aynen devamına ekleyebilirsin. Kanal eklerken, # koymamalısın.

örnek muafnick (ahmet|mehmet|cansu)
örnek kanal (operhelp|help|yardim|chat)

/* Belirtilen Ana-Kod */

Kod:

on *:start:{ if (!$hget(greet)) { hmake greet 100 | hload -s greet greet.hash } }

on *:text:*:#:{
  var %_xs = hsave -s greet greet.hash
  if ($chan == #kontrol) {
    if $regex($1,/^!(ekle|sil|liste)/i) { var %_x = $regml(1)
      if (%_x == ekle) {
        if (!$2 || !$3-) { msg # $nick Eksik bir komut girdiniz, doğru kullanım; !ekle nick mesaj , şeklinde olmalıdır. | return }
        if (!$hget(greet)) { hmake greet 100 | hload -is greet greet.hash }
        hadd -m greet $2 $3-
        msg # Kayıtlarımıza, $2 nick'i başarıyla eklendi.
        msg # Karşılama Mesajı: $3-
        %_xs
      }
      if (%_x == sil) {
        if (!$2) { msg # $nick Eksik bir komut girdiniz, doğru kullanım; !sil nick , şeklinde olmalıdır. | return }
        if (!$hget(greet,$2)) { msg # Böyle bir kullanıcı zaten, bulunmamaktadır. | return }
        msg # Kayıtlarımızdan $2 , başarıyla silindi.
        hdel greet $2
        %_xs
      }
      if (liste isin %_x) {
        _wlist #
      }
    }
  }
}
alias _wlist {
  var %_wl = 1 | while %_wl <= $hget(greet,0).data { var %_w1 = $hget(greet,%_wl).item, %_w2 = $hget(greet,%_wl).data
    msg $1 Nick: %_w1 , Mesaj: %_w2
    inc %_wl
  }
  if (!$hget(greet,%_w1)) { msg $1 hiç bir kayıt bulunmamaktadır. | halt }
}

on *:join:#:{
  if ($regex(#,/(Help|operhelp)/i) || $regex($nick,/(muaf1|muaf2)/i)) { return }
  set -eu5 %_wn $nick | set -eu5 %_wc #
  if ($hget(greet,$nick)) { var %_w2 = $hget(greet,$nick)  |  msg %_wc %_w2   | return }
  if $regex($address($nick,2),/(admin|ircop|oper)/i) {
    whois %_wn
  }
}
raw 313:*:{
  if (%_wn == $2) {
    if (!$6-) {
      if (!$hget(greet,$2)) { msg %_wc Sunucu IRC Operatörü (>> %_wn <<) , %_wc kanalına giriş yaptı. | return }
      else {
        var %_w1 = $2, %_w2 = $hget(greet,$2)
        msg %_wc %_w2
      }
    }
    if $regex($7-,/(Server|Services|Network|Co|Tech)/i) {
      var %_add = $regml(1)
      if (!$hget(greet,$2)) { msg %_wc Sunucu %_add Admin 'i (>> %_wn <<) , %_wc kanalına giriş yaptı. | return }
      else {
        var %_w1 = $2, %_w2 = $hget(greet,$2)
        msg %_wc %_w2
      }
    }
  }
}

Not: Kodu denemedim, ama %99 hatasız çalışacaktır

Benzer Konular
Konu	Konuyu Başlatan	Forum	Cevaplar	Son Mesaj
Kanala girişte oto whois	tonyukuk	Help - Yardım	2	22 Temmuz 2009 13:50