İller arası kaç km, kaç saat?

[L4roXyL]

Evet arkadaşlar can sıkıntısından yazdığım bir kod.
İsteyen alıp kendine göre uyarlayabilir, script-i için dialoglar katarak add-on vb. şeyler haline getirebilir. IRC sunucusu için kanalda kullanıcılara hizmet için kullanılabilir. Bu size ve birazda kod bilginize kalmış.

-

Kodun işlevleri:

1- Kod socket ile verileri webden(illerarasimesafe.com) alır.(Bilgisayarınızda internet bağlantısı gereklidir.)
2- Belirtilen ilk il ile belirtilen ikinci il arasındaki yol mesafesini(km cinsinden) hesablar. Ve ortalama kaç saat olduğunu gösterir.
3- Belirtilen il ile ilçe arasındaki mesafeyi aynı şekilde gösterir.
4- Belirtilen il-ilçe ile ikinci belirtilen il-ilçe arasındaki mesafeyi yine aynı şekilde gösterir.

Kod/code:

;Yazan/Written by: L4roXyL - (Hasan AYDENİZ)
alias -l _ch { 
  if ($1 = _km_lo) { return $replace($lower($2-),ü,u,ı,i,İ,i,I,i,ö,o,ş,s,ğ,g,ç,c) }
  if ($1 = _km_up) { return $upper($replace($2-,ı,I,i,İ)) }
}
alias km { 
  if ($regex($1,/^(ilçe|il)$/i) && $2-3) { 
    %_km_wrng = Uygun sonuç bulunamadı. İl/ilçe isimlerini doğru girdiğinizden emin olun.
    %_km_let = ( $+ $regsubex($2,-,/) - $regsubex($3,-,/) $+ ) | $iif(sock(_km),sockclose _km)
    sockopen _km www.illerarasimesafe.com 80 
    if ($regex($1,/^ilçe$/i)) %_get_link = $+(/?il=,$_ch(_km_lo,$2),&ilce=,$_ch(_km_lo,$3))
    if ($regex($1,/^il$/i)) %_get_link = $+(/?nereden=,$_ch(_km_lo,$2),&nereye=,$_ch(_km_lo,$3))
  }
  else echo -ae Hatalı kullanım. Örnek: /km <il> il-ismi il-ismi -   /km <il> il-ilçe-ismi il-ilçe-ismi - /km <ilçe> il-ismi   ilçe-ismi
}
on *:sockopen:_km: {
  var %_km = $sockname,%_c = sockwrite -n 
  %_c %_km GET %_get_link HTTP/1.1
  %_c %_km Host: illerarasimesafe.com 
  %_c %_km $crlf
}
on *:sockread:_km: {
  var %_k | sockread %_k
  if ($regex(_km,%_k,/^<div id="sonuc"><span id="sonuc-km">(.+)</span><br />$/)) { 
    var %_l = $regml(_km,1) 
    %_km_locc = $iif($token(%_l,2,32),%_l)
    if (!%_km_locc) { echo -ae %_km_wrng | sockclose _km }
  }
  if ($regex(_time,%_k,/<span id="sonuc-saat">Ortalama <font   style="color:#F60;">(.+)</font></span>(</div>|<br   />)/)) {
    var %_time = $regml(_time,1)
    if (%_km_locc) {
      echo -ae $_ch(_km_up,%_km_let) arası: %_km_locc olup, saat'de 100   km hızla $iif(%_time,$iif($v1 != 0 saat 0 dakika,$v1)) $+ 'dır.
    }
  }
}

-
Alias ismi: /km
Ek kullanımlar: /km <il|ilçe>(bunlar arama biçimidir)

-

Kullanım şekli/using:

Bir il ile diğer il arasındaki mesafeyi öğrenmek için: /km il ilk-il-ismi ikinci-il-ismi
Örnek: /km il İstanbul Elazığ

-

Bir ilçe ile diğer ilçe arasındaki mesafeyi öğrenmek için: /km il ilk_il_ismi-ilçe_ismi ikinci_il_ismi-ilçe_ismi
Örnek: /km il İstanbul-Bakırköy Edirne-Havsa

-

Bir il ile o ile ait ilçe arasındaki mesafeyi öğrenmek için: /km ilçe il-ismi ilçesinin_ismi
Örnek: /km ilçe Çanakkale Gülpınar

-

Kodu biraz incelerseniz daha farklı kullanımlar sezebilirsiniz. Kolay gelsin.

L4roXyL - (Hasan AYDENİZ)