Yaptığım Tüm Yardımlar/Kodlar

[L4roXyL]

Tarih: 06-12-2007, 19:09

Sesli harfleri "*" karakteri olarak gösterme.
Kullanım: Reklam.txt içerisindeki kelimeler üzerinde işlev yapar.

on @*:text:*:#:{ 
  var %s = 1,%ss = $lines(reklam.txt) 
  while %s <= %ss {
    if $+(*,$read(reklam.txt,%s),*) iswm $1- { 
      var %o = $remove($v1,*),%p = $regsub(%o,/(a|e|i|u|ü|o|ö|[A-Z])/gi,$chr(42)\1,%o) 
      ban -k # $nick 2 Yasaklı kelime kullandınız: %o 
    } 
    inc %s 
  } 
}

İkinci kullanım:

Örneğin; //echo -: $ok(Nasılsınız?) yaptığında; N*s*ls*n*z? olarak dönecektir.

alias ok { 
  var %1 = $1- 
  var %2 = $regsub(%1,/(a|e|i|u|ü|o|ö|ı)/gi,$chr(42)\1,%1) 
  return %1 
}

[L4roXyL]

Tarih: 06-12-2007, 20:21

Bu kod özele yazan nick kayıtlı değilse ve kufur.txt dosyasından herhangi bir kelimeyi kullandıysa, tüm kanallardan banlamak için kullanılır.

on *:text:*:?: {
  inc -e $+(%,t,$nick) 
  if $($+(%,t,$nick),2) == 1 { 
    .enable #u 
    .who $nick 
  } 
  else {
    var %1 = 1,%2 = $lines(kufur.txt) 
    while %1 <= %2 { 
      if $+(*,$read(kufur.txt,%1),*) iswm $1- && $hmatch(nick,$nick) {
        var %p = $nick 
      } 
      inc %1 
    } 
    var %s = 1,%ss = $comchan($me,0) 
    while %s <= %ss { 
      if $nick ison $comchan($me,%s) { 
        ban -ku900 $comchan($me,%s) %p 2 BAN SEBEBİ.
      } 
      inc %s 
    } 
  } 
}
#u off
raw *:*: { 
  if $numeric == 352 { 
    if r !isincs $7 { 
      haltdef 
      hadd -m nick $6 1 
    } 
  } 
  if $numeric == 315 {
    haltdef 
    .disable #u 
  } 
}
#u end

[L4roXyL]

Tarih: 06-12-2007, 20:34

Kanal menüsünü sağ tıklayarak temizle.txt içerisindeki dosyayı kanala yansıtma.
Not: Kanal temizlemek için kullanılır.

menu channel {
  Temizle:temizle #
}
alias temizle { 
  var %u = 1,%s = $lines(temizle.txt) 
  while %u <= %s {
    msg $1 $read(temizle.txt,%u) 
    inc %u 
  }
}

[L4roXyL]

Tarih: 07-12-2007, 17:37

Belirtilen kanala giren kullanıcıları, belirlenen kanallara random sajoin-lemek.

on !*:join:#belirtilen-kanal:{ 
  var %q = #kanal1 #kanal2 #kanal3 #kanal4 #kanal5,%t = $calc($numtok(%q,32)+1) 
  inc -e %r 
  $iif(%r != %t,sajoin $nick $gettok(%q,%r,32),unset %r) 
}

[L4roXyL]

Tarih: 05-12-2007, 16:50

i) Kufur.txt dosyası üzerinde kanal yazılan text-lere işlem yapmak.
ii) Dosyaya kelime eklemek.
iii) Dosyadan kelime silmek.
iiii) Dosyadaki kelimeleri listemek vs.

;/kekle kelime
alias kekle {
  if $1 {
    if $read(kufur.txt,w,$1) {
      echo -at $1 kelimesi zaten listede. 
      return
    } 
    else { 
      write kufur.txt $1 
      echo -at $1 kelimesi listeye eklendi. 
    }
  }
}

;/ksil kelime
alias ksil {
  if $1 {
    if !$read(kufur.txt,w,$1) {
      echo -st $1 kelimesi listede yok. 
      return
    } 
    else {
      write $+(-dl,$readn) kufur.txt 
      echo -st $1 kelimesi kufur listesinden silindi.
    }
  }
}

;/klist
alias klist {
  var %s = 1,%ss = $lines(kufur.txt) 
  while %s <= %ss { 
    echo -a Kelime: $read(kufur.txt,%s) 
    inc %s 
  }
}

;Esas kod
on @*:text:*:#:{
  var %s = 1,%ss = $lines(kufur.txt) 
  while %s <= %ss { 
    if $+(*,$read(kufur.txt,%s),*) iswm $1- { 
      ban -k # $nick 2 küfür yasak vs. 
    } 
    inc %s
  }
}

[L4roXyL]

Tarih: 08-12-2007, 21:15

Belirtilen kanalda kendi yazdığınız !sebeb [ip] kelimesi ilen belirtilen ip-i gzline/gline vb. listesinde arayıp, banlanma sebebini size/kanala yansıtacak kod.
Kullanım: !sebeb [ip-adresi]

on *:input:#belirtilen-kanal:{
  if $1 == !sebeb && $2 { 
    .enable #x 
    set %ip $2 
    stats g 
  }
}
#x off
raw *:*:{
  if $numeric = 223 {
    haltdef
    var %& = $remove($3,@,*)
    if %ip == %& {
      hadd -m g $replace($7-,$chr(32),$chr(61))
    }
  }
  if $numeric = 219 {
    haltdef
    if !$hget(g) { 
      msg #belirtilen-kanal %ip ip'i bulunamadı. 
      return 
    }
    else {  
      msg #belirtilen-kanal %ip ip'inin atılma sebebi; $replace($hget(g,1).item,$chr(61),$chr(32))
      hfree g
      disable #x
    }
  }
}
#x end

[L4roXyL]

Tarih: 09-12-2007, 00:25

MsnSONG.dll kullanarak sunucudaki kullanıcı sayısını /map komutu ile msn-ye yansıtmak.

alias msnsong { 
  var %dll MsnSong.dll 
  .comreg %dll 
  .comopen msn Msn.Write 
  var %i $com(msn,WriteToMsn,1,bstr,$1-,bstr,$null,bstr,$null) 
  .comreg -u %dll 
  .comclose msn 
}
raw 6:*:msnsong $2 user sayısı: $3

[L4roXyL]

Tarih: 20-01-2008, 00:25

Kanal text gönderirken text içerisinde kanalda bulunan bir nick varsa o nick bold/kalın olarak belirleme.

on *:input:*: {
  if $left($1,1) != / { 
    var %q 1 
    while (%q <= $numtok($1-,32)) { 
      if ($gettok($1-,%q,32) ison $active) { 
        say $replace($1-,$v1,$+($chr(2),$v1,$chr(2))) 
        break 
      } 
      inc %q 
    } 
    haltdef 
  } 
}

[L4roXyL]

Tarih: 05-01-2008, 14:35

Özelinizdeki (/query) nickin clone-si hakkında bilgi veren kod.

on *:active:?: { 
  if $ial($address($active,2),0) >= 2 { 
    inc -e $+(%,p,$active) 
    if $($+(%,p,$active),2) == 1 { 
      var %1 1,%2 
      while %1 <= $ial($address($active,2),0) { 
        %2 = $addtok(%2,$gettok($ial($address($active,2),%1),1, 33 ),32) 
        inc %1 
      } 
      echo $active %2 nickleri aynı hosta sahipler. 
    } 
  } 
}

[L4roXyL]

Tarih: 05-01-2008, 01:08

Kanala giren guest takılı kullanıcılara işlev(uyarı, 2. uyarı ve ban) yapmak için hazırlamış olduğum bir kod.

on *:join:#:$iif($nick == $me,.timerkntrl 0 60 guest #,$iif(guest* iswm $nick,$+(.timer,$v2) 1 30 msg # $+($chr(22),$v2,$chr(22)) nick değiştiriniz vs.))
alias guest {
  if $ialchan(Guest*,$1,0) >= 2 {
    var %t = 1,%y 
     while %t <= $ialchan(Guest*,$1,0) {
      %y = $addtok(%y,$+($chr(22),$gettok($ialchan(Guest*,$1,%t),1,33),$chr(22)),32)
      $iif($hmatch(nick,$gettok($ialchan(Guest*,$1,%t),1,33)),hinc -m nick $gettok($ialchan(Guest*,$1,%t),1,33) 1,hadd -m nick $gettok($ialchan(Guest*,$1,%t),1,33) 1)
      if $hget(nick,$gettok($ialchan(Guest*,$1,%t),1,33)) >= 3 {
        ban -k $1 $gettok($ialchan(Guest*,$1,%t),1,33) 2 Sebeb. 
        $+(.timer,$gettok($ialchan(Guest*,$1,%t),1,33)) off
        hdel -s nick $gettok($ialchan(Guest*,$1,%t),1,33) 
      }
      inc %t
    }
    msg $1 %y nick değişiniz vs.
  }
}