dialog wst {
  title "Windows Başlarken Program Çalıştırmak"
  size -1 -1 150 145
  option dbu
  box "", 1, 1 -1 148 42
  text "Programı Seç:", 4, 5 5 33 8
  edit "", 5, 5 13 140 10, read autohs
  button "Programı Seç", 6, 5 25 46 12
  text "Eklediğiniz Programların Listesi:", 7, 2 43 74 8
  list 8, 1 51 146 79, size vsbar
  button "KAPAT", 9, 41 132 37 12, cancel
  button "Programı Ekle", 11, 54 25 40 12, disable
  button "SiL", 12, 2 132 37 12, disable
  text "www.mIRCdb.com", 2, 104 135 45 8
}

alias wst if (!$dialog(wst)) dialog -m wst wst
alias regread {
  if ($com(rread)) .comclose rread
  .comopen rread wscript.shell
  var %s $com(rread,RegRead,3,bstr,$1-) , %a $com(rread).result
  $iif(!%a,return $false,return %a)
}
alias regwrite {
  if ($com(rwrite)) .comclose rwrite
  .comopen rwrite wscript.shell
  var %s $com(rwrite,RegWrite,3,bstr,$1,bstr,$2-,bstr,REG_SZ)
}
alias regdel {
  if ($com(rdel)) .comclose rdel
  .comopen rdel wscript.shell
  return $com(rdel,RegDelete,3,bstr,$1-)
}
alias ch->p {
  $iif($regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item) == $false,set %item 1,set %item $regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item))
  while (%item) {
    if ($1- == $regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\n $+ %item)) return $true
    dec %item
  }
  unset %item
}
alias load->p {
  $iif($regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item) == $false,set %item 1,set %item $regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item))
  var %i 1
  while (%i <= %item) {
    if ($regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item) != $false) && ($regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\n $+ %i) != $false) did -a wst 8 $regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\n $+ %i)
    inc %i
  }
  unset %item
}

on *:dialog:wst:sclick:*: {
  if ($did == 6) {
    var %file $sfile($mircdir,Dosya Seç)
    if (%file) && ($gettok(%file,-1,46) == exe) { did -ra $dname 5 %file | did -e $dname 11 }
  }
  if ($did == 8) $iif($did(8).seltext,did -e $dname 12)
  if ($did == 12) {
    var %item $regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item)
    while (%item) {
      if ($did(8).seltext == $regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\n $+ %item)) regdel HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\n $+ %item
      dec %item
    }
    var %item $regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item)
    did -d $dname 8 $did(8).sel
  }
  if ($did == 11) {
    if ($ch->p($did(5)) == $true) return $input(Bu program daha önce eklenmiş!,ohud,Hata)
    else {  
      var %item $regread(HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item)
      if (%item == $false) var %item 0
      inc %item
      regwrite HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\n $+ %item $did(5)
      regwrite HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\mIRCdb_Wst\item %item
      did -a $dname 8 $did(5)
      did -r $dname 5 | did -b $dname 11
    }
  }
}
on *:dialog:wst:init:*: load->p