Yaptığım Tüm Yardımlar/Kodlar - Sayfa 9

**L4roXyL** · #81 11 Ekim 2011, 00:48

Tarih: 14-01-2009, 01:19

Bu kod sunucuya giren çıkan kullanıcıları @join-part penceresinde göstermeye yarar.

Kod:

on *:snotice:*:{
  if ($regex($1-,/client (connecting|exiting:)/i)) { 
    var %s = $regml(1) 
    if (!$window(@JOIN-PART)) window -aCk0 @join-part 
    echo -t @join-part $iif(%s = connecting,Giriş: $9-10,$iif(%s = exiting:,Çıkış: $6-7)) 
  }
}

**L4roXyL** · #82 11 Ekim 2011, 00:53

Tarih: 15-01-2009, 08:26

Bu kod herhangi bir kanaldan başkası tarafından kick-lendiğinizde sounds klasöründeki kick.wav dosyasını çalmanıza ve baloncuk uyarısı almanızı sağlar.
Not: Baloncuk uyarısı(/tips - $tip) mIRC 6.31 sürümünden sonra geçerlidir.

Kod:

on *:kick:#:{
  if ($knick == $me && $nick != $me) { 
    .splay -w $mircdirsounds\kick.wav 
    noop $tip(kick,Kicklendiniz.,# kanalında $nick tarafından kicklendiniz.,8,,,,$window(#).wid)
  }
}

**L4roXyL** · #83 11 Ekim 2011, 00:56

Tarih: 15-01-2009, 08:26

Bu kod kanal veya özelde herhangi birisi sizin nickinizi yazdığında sounds klasöründeki connect.wav dosyasının çalmasını sağlar ve /echo ile aktif ekrana uyarı verir.

Kod:

on *:text:$($+(*,$me,*)):*:{
  var %e = echo -aet 
  .splay -w $mircdirsounds\connect.wav 
  if (#) { 
    $iif($active != #,%e INFO: $+($nick,.) # kanalından size seslendi: $qt($1-)) 
  } 
  else $iif($active != $nick,%e $nick özelden size seslendi: $qt($1-)) 
}

**L4roXyL** · #84 11 Ekim 2011, 01:01

Tarih: 15-01-2009, 08:59

Bu kod /gir şeklinde uygulandığında list-de çıkan tüm kanallara girmenize, /cık şeklinde uygulandığında #operhelp ve #help kanalları haric tüm kanallardan çıkmanıza yarar.

Kod:

alias gir set %jp join | .enable #x | list
alias cık set %jp part | .enable #x | list
#x off
raw *:*:{
  if ($regex($numeric,^(32[2-3])$)) { 
    var %: = $regml(1) 
    $iif(%: == 322,$iif(%jp == join,%jp $2,$iif(!$regex($2,/^(#operhelp|#help)$/i),%jp $2)),$iif(%: == 323,.disable #x))
  }
}
#x end

**L4roXyL** · #85 11 Ekim 2011, 01:10

Tarih: 15-01-2009, 09:45

Bu kod bir kanaldan diğer bir kanala belirtilen sayıdaki kullanıcı taşımak için kullanılır. Gayet gelişmiş bir koddur.
Kullanım şekli: /mjoin #aktarılacak-kanal #aktarılan-kanal <kullanıcı-sayısı>
Not: <kullanıcı-sayısı> kısmı boş veya sallamasyon bir sayı yazılırsa tüm userları çekcektir.

Kod:

alias mjoin {
  if ($regex($1,/^#(\w)/i) && $regex($2,/^#(\w)/i)) {
    var %1 = 1,%2 = $iif($iif($nick($1,0) >= $3,$3),$3,$nick($1,0)) 
    while (%1 <= %2) { 
      $iif($nick($1,%1) !ison $2,sajoin $nick($1,%1) $2) 
      inc %1 
    } 
  } 
  else echo $color(info) -eat * /mjoin: Hatalı kullanım: /mjoin #INchan #OUTchan <number>
}

**L4roXyL** · #86 11 Ekim 2011, 01:23

Tarih: 19-01-2009, 23:03

Bu kod kanala giren rumuz içerisinde herhangi bir karakter 3 adet veya fazlası tekrar edilmişse kanaldan uzaklaştırmaya yarar.
Not: {3} kısmından limiti değiştirebilirsiniz.

Kod:

on !*:join:#:{
  if ($regex($nick,/(.+?)\1{3}/)) {
    ban -k # $nick 2 rumuzunuzda, $qt($regml(1)) karakterinden 7+ mevcut olduğundan uzaklaştırıldın vs.
  }
}

**L4roXyL** · #87 11 Ekim 2011, 01:29

Tarih: 07-07-2009, 17:23

Bu kod belirtilen kanal veya özel penceresine belirtilen dosyadaki satırları belirtilen saniye-de bir satır olmak kaydı ile yansıtmanıza yarar.
Kullanım şekli: /rfile #kanal|özel-pencere dosya.txt <saniye>
Örnek: /rfile #deneme deneme.txt 5
Açıklama: #deneme kanalına deneme.txt satılar 5 saniyede bir sırasıyla gönderilecektir.

Kod:

alias rfile {
  if ($regex(rfile,$1,^(-(r|p))$) && $timer(rfile)) { 
    .timerrfile $regml(rfile,1) 
    return 
  } 
  if ($2 && $3) {
    $iif(!$fopen(rfile),.fopen rfile $2) 
    .timerrfile 0 $3 $!iif($fopen(rfile).eof,.fseek -l rfile 1) $(|) .msg $1 $!fread(rfile) 
  }
}

**L4roXyL** · #88 11 Ekim 2011, 01:33

Tarih: 08-07-2009, 01:39

Bu kod scriptizi açtığınızda @bilgi penceresinde nick, yedek nick, IP adresi vb. bilgilerinizi görmenize olanak sağlar.

Kod:

on *:start: {
  if (!$window(@bilgi)) window -ak0 @bilgi
  var %e = echo 4 @bilgi,%c = $+($chr(3),1),%s = $token($readini($nopath($mircini),mIRC,host),2,58) 
  %e Server: %c $+ %s
  %e Aktif $+(nick,:,%c,$chr(32),$iif($me,$v1,Girilmemiş.))
  %e Yedek $+(nick,:,%c,$chr(32),$iif($anick,$v1,Girilmemiş.))
  %e IP $+(adresi,:,%c,$chr(32),$ip)
  %e $+(Tarih/saat,:,%c,$chr(32),$date - $time)
}

**L4roXyL** · #89 11 Ekim 2011, 01:37

Tarih: 08-07-2009, 13:34

Bu kod dosya.txt içerisindeki kelimelerden biri kanala gönderildiğinde aktif ekranda /echo ile uyarı almak için kullanılır.

Kod:

on *:text:*:#:{
  var %1 = 1,%v1 
  while ($read(dosya.txt,%1)) { 
    %v1 = $v1 
    if ($regex($1-,%v1)) { 
      echo -caet action $nick # kanalında belirlediğiniz $+(kelimelerden,$chr(40),%v1,$chr(41)) birini kullandı. 
      break 
    } 
    inc %1 
  }
}

**L4roXyL** · #90 11 Ekim 2011, 01:41

Tarih: 10-07-2009, 23:41

Bu kod sunucuya giren kullanıcılara bad.txt dosyası içerisindeki kelimeleri tarayarak badnick kontolü yaparak, bulunan badnick-in rumuzunu user[random-sayı] şeklinde değiştirir.
Not: Bu kodu kullanabilmek için /os raw svsnick komutunu kullanabilmeniz gerekmektedir.

Kod:

on *:snotice:*client connect*:{
  var %1 = 1 
  while ($read(bad.txt,%1)) { 
    if ($regex($9,/ $+ $v1 $+ /i)) { 
      inc %* 1 
      os raw svsnick $9 $+(user,%*,$r(0,999)) 0:0 
      break 
    } 
    inc %1
  }
}