mIRC Scripting
Sayfa 2 Toplam 3 Sayfadan 1 2 3
Konuya ait 40 Mesajı başka Sayfada göster

mIRC Scripting (https://www.mircscripting.net/)
-   Snippets - Parça kodlar (https://www.mircscripting.net/snippets-parca-kodlar/)
-   -   Yaptığım Tüm Yardımlar/Kodlar (https://www.mircscripting.net/snippets-parca-kodlar/537-yaptydhym-tuem-yardymlar-kodlar.html)

L4roXyL 07 Ekim 2011 17:05
Tarih: 02-02-2008, 23:19

Bu kod mIRC üzerinden herhangi bir sunucuya bağlanmaya kalktığınızda, eğer dosya.txt-deki rumuzlardan birisi ile bağlanıyorsanız rumuzunu mIRCUser-randomsayı şeklinde değiştirmeye yarar. Genellikle başkalarının scriptlerine güvenlik önlemi için kullanılır.

Kod:
alias -l kntrl {
  var %s = 1
  while ($read(dosya.txt,%s)) {
    if ($regex($1,/ $+ $v1 $+ /i))) {
      nick $+(mIRCUser,-,$r(1,999))
      break
    }
    inc %s
  }
}
on *:connect:kntrl $me

L4roXyL 07 Ekim 2011 17:13
Tarih: 03-02-2008, 04:30

Bu kod scriptini açtığınızda belirlediğiniz günlere göre fullname-inizi değiştirmenize olanak sağlar.

Kod:
alias -l days return $replacecs($day,Monday,Pazartesi,Tuesday,Salı,Wedn esday,Çarşamba,Thursday,Perşembe,Friday,Cuma,Satur day,Cumartesi,Sunday,Pazar)
on *:start: {
  if ($days = Pazartesi) set %stnm Pazartesi-ismi.
  if ($days = Salı) set %snm Salı-ismi.
  if ($days = Çarşamba) set %snm Çarşamba-ismi.
  if ($days = Perşembe) set %snm Perşembe-ismi.
  if ($days = Cuma) set %snm Cuma-ismi.
  if ($days = Cumartesi) set %snm Cumartesi-ismi.
  if ($days = Pazar) set %snm Pazar-ismi.
}

L4roXyL 07 Ekim 2011 17:18
Tarih: 03-02-2008, 15:23

Bu kod herhangi bir kullanıcı nickinizi özelden veya kanaldan yazdığı zaman, mIRC simge veya tray konumunda ise, flash ile uyarı almanızı sağlar.

Kod:
on ^*:text:$($+(*,$me,*)):*: {
  if ($regex($appstate,^(minimized|tray)$)) {
    flash -r30 $+($nick,-,$iif(#,#,Özelden))
  }
}

L4roXyL 07 Ekim 2011 17:23
Tarih: 08-02-2008, 14:02

Bu kod kanala başkaları tarafından gönderilen text-ler içerisinde dosya.txt dosyasında bulunan "gelen yazı | gidecek yazı" şeklindeki satılarda, "gelen yazı" kısmında arama yapar. Eşleşme bulduğunda, "gidecek yazı" kısmını kişiye cevap olarak atacaktır.

Kod:
on *:text:*:#: {
  if ($read(dosya.txt,s,$1)) {
    var %s = $gettok($replacecs($read(dosya.txt,$readn),$chr(124),$(|)),2,124)
    msg # %s
  }
}

L4roXyL 07 Ekim 2011 17:29
Tarih: 07-02-2008, 19:56

Bu kod belirtilen sayıdan fazla kullanıcı bulunan kanallara girmeye yarar.
Kodu kullanma şekli: /gir <sayı>

Kod:
alias gir .enable #k | list -min $1
#k off
raw *:*:{
  if ($numeric = 322) {
    if ($3 >= 50) join $2
  }
  if ($numeric = 323) {
    .disable #k
  }
}
#k end

L4roXyL 07 Ekim 2011 17:42
Tarih: 07-02-2008, 23:18

Bu kod kanala giren nicklerin, daha önce hangi nick-lerden giriş yaptığını gösterir.

Kod:
on !*:join:#: {
  if ($hmatch(#,$+($site,*),0) >= 2) {
    kntrl # $site $nick
  }
  hadd -m # $+($site,½,$nick) 1
}
alias kntrl {
  var %1 1,%2
  while ($hmatch($1,$+($2,*),%1)) {
    var %& = $gettok($v1,2,189)
    if (%& != $3) {
      %2 = $addtok(%2,%&,32)
    }
    inc %1
  }
  $iif($gettok(%2,2,32),echo $colour(join) -t $1 *** Bilgi: $3 nick'i daha önce; %2 nicklerinden giriş yaptı.)
}

L4roXyL 07 Ekim 2011 18:24
Tarih: 08-02-2008, 13:56

Bu kod sunucudan çıkan kullanıcıları ayrı pencerede(@network ve @network2) göstermeye yarar. Kodlardan birisi(on quit) IRCop flagları gerektirmez. Diğeri (on snotice) gerektirir.

Kod:
on *:quit: {
  $iif(!$window(@network),window -Cnak0 @network)
  echo $colour(quit) -t @network (<= Çıkış) Nick: $nick - tam adresi: $gettok($address($nick,5),2,33)
}
on *:snotice:*client exiting*: {
  $iif(!$window(@network2),window -Cnak0 @network2)
  echo $colour(info) -t @network2 (<= Çıkış) Nick: $6 - IP adresi: $remove($gettok($7,2,64),$chr(41))
}

L4roXyL 07 Ekim 2011 19:04
Tarih: 08-02-2008, 20:20

Bu kod sunucuya giren kullanıcıları ayrı sayfada gösterir(@giris). Ve o ayrı sayfadaki nick üzerine tıkladığınızda o kişiyi sunucudan uzaklaştırır(/gline)

Kod:
on *:snotice:*client connect*: {
  $iif(!$window(@giris),window -Cnak0 @giris)
  echo $colour(info) -t @giris Giriş yaptı: $+($chr(40),$9,$chr(41))
}
on ^*:hotlink:(*):@giris:if ($left($1,1) == $chr(40)) return | else return
on *:hotlink:*:@giris:gline $remove($1,$chr(40),$chr(41)) :gline sebebi.

L4roXyL 07 Ekim 2011 19:13
Tarih: 08-02-2008, 20:57

Bu kod sunucuya giren son kullanıcıyı belirtilen değişkene kayıt eder. Ve status penceresinde son giren kullanıcıya tıkladığınız zaman /gline ile sunucudan uzaklaştırılır.

Kod:
on *:snotice:*client connect*:set %& $9
on ^*:hotlink:%&:status window:return
on *:hotlink:*:*:gline $1 :gline-sebeb.

L4roXyL 07 Ekim 2011 19:16
Tarih: 08-02-2008, 20:45

Bu kod kanala giren kullanıcıya /userip uygulayıp aynı kanalda gerçek IP-sini göstermeye yarar. Bunu yapabilmek için IRCop flaglarına sahip olmalısınız.

Kod:
on ^!*:join:#:haltdef | set %& # | .enable #j | userip $nick
#j off
raw 340:*: {
  haltdef
  var %n = $gettok($2,1,61)
  echo $colour(join) -t %& *** Giriş: %n $+($chr(40),$gettok($2,2,43),$chr(41))
  .disable #j
}
#j end

L4roXyL 07 Ekim 2011 19:20
Tarih: 08-02-2008, 23:13

Bu kod statusde bulunan nickleri ayrı bir pencerede(@slist) listemek ve işlevler yapmak için kullanılır. Kodu kullanmak için /slist yapmanız yeterlidir.

Kod:
alias slist .enable #r | who
#r off
raw *:*: {
  haltdef
  if ($numeric = 352) {
    $iif(!$window(@slist),window -Cak0dl +L @slist 0 0 200 300)
    if ($chr(35) !isin $2) {
      inc %1
      aline 5 @slist $+(%1,-,$6))
    }
  }
  if ($numeric = 315) {
    if ($window(@slist)) {
      aline @slist $chr(160)
      aline @slist Toplam: $+($chr(2),%1,$chr(2)) adet kullanıcı.
    }
    unset %1
    .disable #r
  }
}
#r end

L4roXyL 07 Ekim 2011 19:31
Tarih: 16-02-2008, 19:50

Bu kod belirtilen kanaldaki yetkililere /whois çeker ve idle süresi, belirtilen saniyeden düşük olan yetkilileri de-op/sop/hop vs. konumuna getirir.
Kod kullanım şekli: /idletara #kanal-ismi <saniye>

Kod:
alias idletara {
  if ($left($1,1) = $chr(35) && $2 && $nick($1,0,@&%.~) != 0) {
    .enable #kk
    set %s $2
    set %k $1
    set %op $nick(#,0,@%&.~)
    var %1 = 1
    while (%1 <= %op) {
      whois $nick(#,%1,@)
      inc %1
    }
  }
}
#kk off
raw *:*: {
  haltdef
  if ($numeric = 317) {
    if ($3 >= %s) {
      if ($2 != $me) {
        mode %k -oaqh $2 $2 $2 $2
        .msg $2 idle süreniz, $qt(%s) saniyeyi aştığı için de-op/sop vs. edildiniz.
      }
    }
  }
  if ($numeric = 318) {
    inc %&
    if (%& = %op) {
      unset %op %k %&
      .disable #kk
    }
  }
}
#kk end

L4roXyL 07 Ekim 2011 19:37
Tarih: 17-02-2008, 22:16

Bu kod sunucuya giren/çıkan kullanıcıları ayrı bir pencerede(@giriş/çıkış) gösterir ve nicklerin üzerine tıkladığında sunucudan uzaklaştırmanıza yarar.

Kod:
on *:snotice:*: {
  if (*client connect* iswm $1-) {
    var %n = $+(",$9,"),%i = $remove($gettok($10,1,64),$chr(40)),%ip = $remove($gettok($10,2,64),$chr(41))
    $iif(!$window(@giriş/çıkış),window -nCk0 @giriş/çıkış)
    echo -te @giriş/çıkış => Giriş: $replacecs(%n,",$+($chr(3),0,",$chr(3))) ! %i @ %ip
  }
  if (*client exiting* iswm $1-) {
    var %nn = $+(",$6,"),%ii = $remove($gettok($7,1,64),$chr(40)),%ipp = $remove($gettok($7,2,64),$chr(41))
    $iif(!$window(@giriş/çıkış),window -nCk0 @giriş/çıkış)
    echo -te @giriş/çıkış <= Çıkış: $replacecs(%nn,",$+($chr(3),0,",$chr(3))) ! %ii @ %ipp
  }
}
on ^*:hotlink:"*":@giriş/çıkış:return
on *:hotlink:*:@giriş/çıkış:gline $remove($1,") :sebeb.

L4roXyL 10 Ekim 2011 18:43
Tarih: 15-04-2008, 22:50

Bu kod belirtilen kanala giren kullanıcının rumuzu içerisinde "guest" takısı varsa, uyarı yapıp belirtilen süre sonra kullanıcı nick değişmezse kanaldan uzaklaştırmanıza yarar.

Kod:
on !*:join:#: {
  if ($regex($nick,/guest/i)) {
    !msg # $nick Uyarı mesajınız.
    $+(timer,$nick) 1 30 ban -k # $nick 2 nickini değiştir vs.
  }
}
on !*:nick:$iif($timer($nick),$+(.timer,$v1) off)
30 olan yer belirtilen saniyedir. Değiştirebilirsiniz.

L4roXyL 10 Ekim 2011 18:49
Tarih: 16-04-2008, 17:22

Bu kod kanalda(opsanız bknz: @*:text:*:#:) belirtilen saniye içerisinde belirtilen tekrar mesajı gönderilirse kullanıcıyı kanaldan uzaklaştırır.

Kod:
on @*:text:*:#: {
  if (!$regex($nick(#,$nick).pnick,@|%|&|~|(\+))) {
    hinc -mu4 fld $+($nick,#,$sha1($1-)) 1
    if ($hget(fld,$+($nick,#,$sha1($1-))) = 3) {
      ban -ku300 # $nick 2 BAN SEBEBİ.
      hdel fld $+($nick,#,$sha1($1-))
    }
  }
}

L4roXyL 10 Ekim 2011 18:54
Tarih: 19-04-2008, 20:53

Bu kod nicklist-den seçilen nick-i kanaldan 6 maska ban atacak şekilde banlamanıza yarar.

Kod:
alias F6 {
  if ($snick($active,0) >= 1) {
    var %1 = 1,%2 = $snick($active,0)
    while (%1 <= %2) {
      mode $active +b $snick($active,%1) 
      allban $active $snick($active,%1)
      inc %1
    }
  }
}
allban {
  var %s = 0
  while (%s <= 5) {
    ban $1 $2 %s
    inc %s
  }
  kick $1 $2 KICK SEBEBİ.
}

L4roXyL 10 Ekim 2011 18:59
Tarih: 01-05-2008, 20:46

Bu kod kanalda selam/slm/s.a vs. kelimelerini yazan kullanıcılara oto-selam vermek için kullanılır. Flood süresi 30 saniyedir değiştirebilirsiniz.

Kod:
on *:text:*:#: {
  if ($regex($1-,/(selam|slm|s\.a)/i)) {
    inc -eu30 $+(%,slm,$nick) 1
    if ($($+(%,slm,$nick),2) == 1) .msg # $qt($nick) a.s vs.
  }
}

L4roXyL 10 Ekim 2011 19:05
Tarih: 30-04-2008, 18:44

Bu kod kanala 5 saniye içerisinde 4 veya fazlası giriş yapıldığında, giren tüm nickleri kanaldan banlar ve kanalın modlarını +RM yapar.

Kod:
on !*:join:#:{
  if ($regex($nick(#,$me).pnick,@|&|~|%|(\+))) {
    hadd -mu5 # $+(#,½,$nick) 1
    if ($hget(#,0).item >= 4) {
      mode # +MR
      msg # Kanal modları değişti vs.
      var %1 = $v1,%2 = 1
      while (%2 <= %1) {
        ban -k # $removecs($hget(#,%2).item,#,½) 2 BAN SEBEBİ.
        inc %2
      }
    }
  }
}

L4roXyL 10 Ekim 2011 19:12
Tarih: 01-05-2008, 22:42

Bu kod(lar) kanala gönderilen action mesajlarında küfür vb. olarak tanımladığınız kelimeleri arar ve işlem yapar. Aynı zamanda küfür listesine ekleme/silme/listeleme vs. işlemlerde yapabilirsiniz. Kod zaten yeterince açık bir şekilde yazılmıştır.

Kod:
;Event (on action)
on @*:action:*:#:bdwchk # $nick $1-

;(/bdwchk): /bdwchk #kanal-ismi nick mesaj
alias bdwchk {
  var %1 = 1,%2 = $iif($hget(bdw,0).item >= 1,$v1)
  while (%1 <= %2) {
    if ($regex($3-,$hget(bdw,%1).item)) {
      ban -k $1 $2 5 BAN SEBEBİ.
      break
    }
    inc %1
  }
}

;(/bdwekle): /bdwekle kelime (Listeye kelime ekler)
alias bdwekle {
  if ($1) {
    if (!$hget(bdw,$1)) {
      hadd -m bdw $1 1
      hsave -i bdw bdw.hash
      echo -at $1 kelimesi listeye eklendi.
    }
    else echo -at $1 kelimesi listede.
    return
  }
  else echo -at Kelime girmediniz.
}

;(/bdwsil): /bdwsil kelime (Listeden kelime siler)
alias bdwsil {
  if ($1) {
    if ($hget(bdw,$1)) {
      hdel bdw $1
      hsave -i bdw bdw.hash
      echo -at $1 kelimesi listeden silindi.
    }
    else echo -a $1 kelimesi listede yok.
    return
  }
  else echo -at Kelime girmediniz.
}

;(/bdwlist): /bdwlist (Listeyi sıralar)
alias bdwlist {
  if (!$hget(bdw) || $hget(bdw,0).item < 1) echo -at Liste boş.
  else $iif(!$window(@Bdwlist),window -adlCk0 +L @Bdwlist 0 0 200 200)
  var %s = 1
  while (%s <= $hget(bdw,0).item) {
    aline @Bdwlist $hget(bdw,%s).item
    inc %s
  }
}

;on start event(Tabloyu yükletmek için)
on *:start: {
  if ($isfile(bdw.hash)) {
    hmake bdw 50
    hload -i bdw bdw.hash
  }
}

L4roXyL 10 Ekim 2011 19:17
Tarih: 04-05-2008, 21:53

Bu kod kanalda belirtilen nicklerden herhangi birisi(nick1, nick2 ve ya nick3) !at nick yaptığı zaman o kullanıcıyı bulunduğu tüm kanallardan uzaklaştırır.

Kod:
on *:text:!at* &:#: {
  if ($regex($nick,/^(nick1|nick2|nick3)$/i)) {
    var %s = 1,%q = $comchan($2,0)
    while (%s <= %q) {
      ban -k $comchan($2,%s) $2 BAN SEBEBİ.
      inc %s
    }
  }
}

L4roXyL 10 Ekim 2011 19:21
Tarih: 05-05-2008, 17:42

Bu kod kanalda kullanıcılar prefix/mod (+q,v,h,o,a) aldıkları(+mod) zaman uyarı yapmanıza yarar.

Kod:
on *:rawmode:#: {
  if ($regex($left($1,1),\+)) {
    if ($regex($remove($1,+),q))  msg # $2 kanal sahibi konumuna geçti. M-by: $qt($nick)
    if ($regex($remove($1,+),a))  msg # $2 protect konumuna geçti. M-by: $qt($nick)
    if ($regex($remove($1,+),o))  msg # $2 operator konumuna geçti. M-by: $qt($nick)
    if ($regex($remove($1,+),h))  msg # $2 halfop konumuna geçti. M-by: $qt($nick)
    if ($regex($remove($1,+),v))  msg # $2 voice konumuna geçti. M-by: $qt($nick)
  }
}

L4roXyL 10 Ekim 2011 19:24
Tarih: 05-05-2008, 22:48

Bu kod sunucuya giren kullanıcıya, giriş yapan kaçıncı kullanıcı olduğunu belirtir ve sozler.txt dosyasından random bir veri gönderir.

Kod:
on *:snotice:*client conn*: {
  inc %1
  msg $9 Sunucuya hoşgeldin vs. Giren $+(%1,.) kişisin.
  msg $9 $read(sozler.txt)
}

L4roXyL 10 Ekim 2011 19:43
Tarih: 06-05-2008, 16:19

Bu kod #sop(değişebilirsiniz) kanalına girdiğinizde, kanaldaki kullanıcıların idle sürelerine bakarak;
- 10 dakikayı geçen kullanıcılara UYARI
- 20 dakikayı geçen kullanıcılara UYARI + KILL
İşlemlerini uygular.
Bu tarama işlemi kanala girdiğiniz andan itibaren 600 saniye(10 dakikada) bir gerçekleşir.

Kod:
on me:*:join:#SOP:idlechk # | .timer 0 600 idlechk #
alias idlechk {
  warning
  .enable #q
  if ($1) {
    var %1 = 1
    while (%1 <= $nick($1,0,@)) {
      if ($regex($removecs($nick($1,%1,@).pnick,$nick($1,%1,@)),^@$)) {
        hinc -m ttl total 1
        whois $nick($1,%1,@)
      }
      inc %1
    }
  }
}
alias warning {
  set %w1 idle süreniz 10 dakikayı geçmiştir. Cevap ver vs.
  set %w2 idle süresi 20 dakikayı geçtiği için uzaklaştırıldı.
  set %w3 idle süreniz 20 dakikayı geçtiği için uzaklaştırıldınız.
}
#q off
raw *:*: {
  haltdef
  if ($regex($numeric,^317$)) {
    if ($3 >= 600 && $3 < 1200) {
      msg #sop $qt($2) %w1
    }
    if ($3 >= 1200) {
      kill $2 %w3
      msg #sop $qt($2) %w2
    }
  }
  if ($regex($numeric,^318$)) {
    inc %&
    if (%& = $hget(ttl,total)) {
      unset %& 
      hfree ttl
      .disable #q
    }
  }
}
#q end

L4roXyL 10 Ekim 2011 20:42
Tarih: 09-05-2008, 21:06

Bu kod özelde konuştuğunuz kişinin nick-ini arkaplan/background olarak kaydetmenizi sağlar. HD şişmesine sebeb olmaz, özel penceresi kapanınca resim otomatik silinir.

Kod:
alias npaint {
  if ($1 && $2) {
    var %win = $+(@,$1)
    window -pah %win 0 0 200 100
    drawtext -ro %win $rgb(112,121,11) Tahoma 19 60 20 $2
    drawsave -b32 %win $+($1,.,bmp)
    window -c %win
  }
}
on *:open:?:*:{
  if ($isfile($+($nick,.,bmp))) background -p $nick $+($nick,.,bmp)
}
on *:close:?:{
  if ($isfile($+($target,.,bmp))) {
    .remove -b $+($target,.bmp)
    .remini mIRC.ini background $target
  }
}

L4roXyL 10 Ekim 2011 20:48
Tarih: 09-05-2008, 18:19

Bu kod !bilgi nick olarak kullanıldığı zaman, kişinin auth-code bilgisini belirlediğiniz #kanal -a yansıtır.

Kod:
on *:text:!bilgi * &:#:.enable #n | ns auth $2
#n off
on *:notice:*:?:{
  if ($nick == nickserv) {
    msg #kanal $1-
    .disable #n
  }
}
#n end

L4roXyL 10 Ekim 2011 21:11
Tarih: 09-05-2008, 19:07

Bu kod herhangi bir kanalda !prefix yaptığınızda, size +qaohve modlarını verir. Eğer !deprefix yaparsanız, bu modları geri alırsınız.

Kod:
on *:input:#:{
  if ($regex($1,^(!prefix|!deprefix)$)) {
    mode # $iif($left($1,3) = !de,-,+) $+ qaohve $str($+($me,$chr(32)),6)
  }
}

L4roXyL 10 Ekim 2011 21:15
Tarih: 09-05-2008, 22:09

Bu kod 30 dakikada bir kendinize idle kontrolu yaparak, eğer idle süresi belirtilen süreyi(saniye cinsinden) geçmişse /away konumuna otomatik geçmenize yarar.

Kod:
on *:connect:.timer 0 1800 idlekntrl 1800
alias idlekntrl {
  if ($idle >= $1 && !$away) {
    away AWAY-MESAJIN.
  }
}

L4roXyL 10 Ekim 2011 22:40
Tarih: 11-05-2008, 23:57

Bu kod kişiye whois çektiğinizde kişinin "bağlantı süresini, konuşmadığı süreyi, bağlantı zamanını" türkçe ve düzenli olarak gösterilmesine yarar.

Kod:
alias -l days return $replacecs($1,Monday,Pazartesi,Tuesday,Salı,Wednesday,Çarşamba,Thursday,Perşembe,Friday,Cuma,Saturday,Cumartesi,Sunday,Pazar)
alias -l idl return $replace($1-,Secs,$+($chr(32),Saniye),Sec,$+($chr(32),Saniye),Mins,$+($chr(32),Dakika),Min,$+($chr(32),Dakika),Hrs,$+($chr(32),Saat),Hr,$+($chr(32),Saat),Days,$+($chr(32),Gün),Day,$+($chr(32),Gün),Wks,$+($chr(32),Hafta),Wk,$+($chr(32),Hafta))
alias -l cnnt return $idl($duration($calc($ctime - $1)))
raw 317:*: {
  echo -a * Bağlanış: $days($asctime($4,$+($chr(40),dddd,$chr(41) dd/mm/yyyy,) - HH:nn:ss))
  echo -a * Konuşmadığı süre: $idl($duration($3))
  echo -a * Bağlı olduğu: $cnnt($4) | haltdef
}

L4roXyL 10 Ekim 2011 22:46
Tarih: 12-05-2008, 22:49

Bu kod /stats k -den gelen verilere bakarak #kanal kanalında !ip <ip-adresi> komutu kullandığınızda belirttiğiniz IP adresini listede arar ve bulunan IP'nin atılma sebebini belirtilen kanala yansıtır.

Kod:
on *:text:!ip* &:#kanal:{
  .enable #g
  set %ip $2
  stats k
}
#g off
raw *:*:{
  if ($regex($numeric,^216$)) {
    if ($3 == %ip) {
      set %ss $4-
    }
  }
  if ($regex($numeric,^219$)) {
    if (%ss) {
      msg #kanal %ip ipinin atılma sebebi: %ss
    }
    else {
      msg #kanal %ip ip'i banlı değil.
    }
    unset %ss %ip
    .disable #g
  }
}
#g end

L4roXyL 10 Ekim 2011 22:53
Tarih: 12-05-2008, 18:04

Bu kod herhangi bir IDENT'in sunucu üzerinde en fazla belirlediğiniz limit kadar kullanılmasına izin verir. Belirlediğiniz limit aşılırsa, giren kişilere kill atılır. Kod giriş çıkışları otomatik kontrol eder ve sayımı girdi(inc)/çıktı(dec) şeklinde tutar.

Kod:
on *:snotice:*: {
    if (*client conn* iswm $1-) {
      var %i = $gettok($remove($10,$chr(40)),1,64)
      if ($hget(ident,%i) >= 6) kill $9 KILL SEBEBİ.
      else hinc -m ident %i 1
    }
    if (*client exiting* iswm $1-) {
      var %ii = $gettok($remove($7,$chr(40)),1,64)
      $iif($hget(ident,%ii) >= 1,hdec ident %ii 1)
    }
}
6 olarak belirtilen yer limittir. Değiştirebilirsiniz.

L4roXyL 10 Ekim 2011 23:05
Tarih: 13-05-2008, 18:34

Bu kod belirtilen kanal veya kanaldaki herhangi bir nick'e kural.txt dosyası içerisindeki kuralları göndermenize yarar.

Kullanım şekilleri:

- /kural #kanal (kanaldaki tüm @(op) - &(sop) - %(halfop) kullanıcılarına göndermek için)
- /kural nick (herhangi bir kullanıcıya göndermek için)

Kod:
alias kural {
  if ($1 ischan || $1 ison active) {
    var %1 = 1
    while (%1 <= $nick($1,0)) {
      if ($regex($nick($1,$nick($1,%1)).pnick,@|&|%)) {
        okut $nick($1,%1)
      }
      inc %1
    }
  }
}
alias okut {
  var %2 = 1
  while ($read(kural.txt,%2)) {
    msg $1 $v1
    inc %2
  }
}

L4roXyL 10 Ekim 2011 23:16
Tarih: 13-05-2008, 23:46

Bu kod belirlediğiniz nick-i ortak tüm kanallardan akick-e almanızı sağlar.
Kullanım şekli: /allkick <nick> <akick sebebi>

Kod:
alias allkick {
  if ($1) {
    var %1 = 1
    while (%1 <= $comchan($1,0)) {
      if ($regex($nick($comchan($1,%1),$me).pnick,@|&|~|%) || $regex($usermode,A|a|N|C)) {
        cs akick $comchan($1,%1) add $address($1,2) $2-
        cs akick $comchan($1,%1) enforce
      }
      inc %1
    }
    var %2 %1 - 1
    echo -at %2 kanalda akick uyguladınız.
  }
}

L4roXyL 10 Ekim 2011 23:20
Tarih: 14-05-2008, 22:43

Bu kod belirtilen kanaldaki tüm kullanıcılara belirlediğini text-i göndermenizi sağlar.
Kullanım şekli: /msgall #kanal <mesaj>

Kod:
alias msgall {
  if ($1 ischan) {
    var %1 = 1
    while (%1 <= $nick($1,0)) {
      msg $1 $2-
      inc %1
    }
  }
}

L4roXyL 10 Ekim 2011 23:32
Tarih: 16-05-2008, 21:07

Bu kod belirtilen #kanal -da atılan kick-leri detaylı bir şekilde kick.txt dosyasına kaydeder ve yine belirtilen kanalda !kick komutunu uygulayan nick-e ait bir kick-list kaydı varsa bu listeyi sıralar.
Kullanım şekli: !kick

Kod:
on !*:kick:#kanal: {
  hinc -m kick $nick 1
  hsave -i kick kick.hsh
  write kick.txt Saat: $time - Kick atan: $nick - Kicklenen: $knick - Sebeb: $1-
}
on *:text:*:#kanal: {
  if ($regex($1,/^!kick$/i) && $nick isreg #) {
    if ($hget(kick,$nick)) msg # Attığınız kick sayısı: $v1
    else msg # Kick uygulamamışsınız.
  }
  if ($regex($1,^!list$)) {
    var %1 = 1
    while (%1 <= $lines(kick.txt)) {
      msg # $read(kick.txt,%1)
      inc %1
    }
  }
}
on *:start:{
  if ($isfile(kick.hsh)) {
    hmake kick 50
    hload -i kick kick.hsh
  }
}

L4roXyL 10 Ekim 2011 23:49
Tarih: 17-05-2008, 16:50

Bu kod yine üstek üzerine yazmış olduğum gelişmiş bir badnick tarama kodudur.

Kod neler yapar?

- Herhangi bir kanala girdiğiniz-de "bad" tablosuna eklemiş olduğunuz ve badnick niteliği taşıyan kelimeleri kanaldaki tüm kullanıcılarda arar.
- Bulunan sonuçları size /echo mesajı ile gösterir.
- Tarama sonunda f9 tuşuna basarsanız son taramaya yakalanan tüm nickleri kanaldan uzaklaştırır.
- /badd <kelime> şeklinde badnick listesine kelime ekleyebilirsiniz.
- /bdel <kelime> şeklinde badnick listesinden belirtilen kelimeyi silebilirsiniz.
- /blist komutunu kullanarak listeyi görebilirsiniz.
- CTRL + f9 kombinasyonunu kullanarak tespit edilen badnickleri görebilirsiniz.

Not: Kodları (aliases - ALT + D) kısmına ekleyiniz.

Kod:
chk {
  var %1 = 1
  while (%1 <= $hget(bad,0).item) {
    if ($ialchan($+(*,$hget(bad,%1).item,*),$1,0) == 1 && >= 0) {
      hadd -m $1 $ialchan($+(*,$hget(bad,%1).item,*),$1,1).nick 1
    }
    else {
      chk2 $1 $+(*,$hget(bad,%1).item,*)
    }
    inc %1
  }
  echo $colour(info) $1 $timestamp $iif($hget($1,0).item >= 1,Bulunan badnick sayısı: $hget($1,0).item,Badnick bulunamadı.)
  echo $colour(info) $1 $timestamp Nickleri görüntülemek için: CTRL + F9 tuşuna basınız.
  echo $colour(info) $1 $timestamp $iif($regex($nick($1,$me).pnick,@|&|%|~),$iif($regex($usermode,a|A|N|C),Nickleri kanal'dan atmak için: F9 tuşuna basınız.),Kanaldan atma yetkiniz yok.))
}
chk2 {
  if ($1 && $2) {
    var %& = 1
    while (%& <= $ialchan($2,$1,0)) {
      hadd -m $1 $ialchan($2,$1,%&).nick
      inc %&
    }
  }
}
cF9 {
  if ($hget($active)) seen $active
}
seen {
  var %t = 1,%tt
  while (%t <= $hget($1,0).item) {
    %tt = $addtok(%tt,$hget($1,%t).item,32)
    inc %t
  }
  echo $colour(info) $1 $timestamp Tespit edilen badnickler: %tt
}
F9 {
  if ($hget($active)) bans $active 
  else diğer komut
}
bans {
  var %- = 1
  while (%- <= $hget($1,0).item) {
    ban -k $1 $hget($1,%-).item 2 SEBEB.
    inc %-
  }
  %// = %- - 1
  echo $colour(info) $1 $timestamp Atılan nick sayısı: %//
  hfree $1
}
badd {
  $iif(!$1,echo -at Kelime girmediniz.,$iif($hget(bad,$1),echo -at $1 kelimesi listede.,hadd -m bad $1 1))
  hsave -i bad bad.hsh
}
bdel {
  $iif(!$1,echo -at Kelime girmediniz.,$iif(!$hget(bad,$1),echo -at $1 kelimesi listede değil.,hdel bad $1))
  hsave -i bad bad.hsh
}
blist {
  window -Caldk0 +L @Bad-words 0 0 200 400
  var %- = 1
  while (%- <= $hget(bad,0).item) {
    aline @bad-words $+(%-,-) $hget(bad,%-).item
    inc %-
  }
}
on me:*:join:#:.ial on | who # | .timer 1 2 chk #
on *:start: {
  if ($isfile(bad.hsh)) {
    hmake bad 50
    hload -i bad bad.hsh
  }
}

L4roXyL 10 Ekim 2011 23:54
Tarih: 29-11-2008, 23:32

Bu kod kanaldaki herkeze seslenmek için kullanılır. Kodu kullanmak için herhangi bir kanal penceresinde; /users <mesaj> yapabilirsiniz.

Kod:
alias users {
  if ($active ischan) {
    var %s = 1,%n
    while ($nick($active,%s)) {
      %n = $addtok(%n,$v1,32)
      inc %s
    }
    say $remove(%n,$me) $1-
  }
}

L4roXyL 11 Ekim 2011 00:01
Tarih: 06-12-2008, 16:15

Bu kod özelinizi açmaya/kapatmaya ve karşı kullanıcıya geri-bildirim yapmanıza olanak sağlar.

Kod:
on ^*:open:?:*:{
  if (%closed) {
    inc $+(%,rumuz,$nick) 1
    if ($($+(%,rumuz,$nick),2) = 1) {
      msg $nick Özelim kapalıdır. Yazdıklarınız bana ulaşmamakta.
    }
    return
  }
}
menu channel,status,query {
  Özel aç/kapa
  .Özeli kapat:set %closed 1 | echo -ea -: Özeliniz konuşmaya kapatıldı.
  .Özeli aç:unset %closed %*rumuz* | echo -ea -: Özeliniz konuşmaya açıldı.
}

L4roXyL 11 Ekim 2011 00:23
Tarih: 13-12-2008, 18:27

Bu kod kanala giriş yapan kullanıcının varsa daha önceki nicklerini giriş bilgisinde gösterir.
Not: Tüm veriler HD-ye kaydolur ve açılışta yükletilir.

Kod:
on !^*:join:#: {
  hadd -m # $nick $site
  hsave -i # # $+ .chans
  if ($hfind(#,$site,0).data >= 2) {
    var %s = 1,%q
    while (%s <= $hfind(#,$site,0).data) {
      %q = $addtok(%q,$hfind(#,$site,%s).data,32)
      inc %s
    }
    echo $color(join) # * Giriş: $nick $+($chr(40),$remove($address($nick,0),*,!),$chr(41)) $&
      - Önceki nickleri: $+($chr(40),$remove(%q,$nick),$chr(41))
    return
  }
}
on *:start:noop $findfile($mircdir,*.chans,0,.timer 1 0 hmake $token($nopath($1-),1,46) $(|,) hload -i $token($nopath($1-),1,46) $nopath($1-))

L4roXyL 11 Ekim 2011 00:31
Tarih: 21-12-2008, 21:56

Bu kod kanal ve özele gönderdiğiniz text/yazı(ların) «YAZI» şeklinde çıkmasını sağlar.

Kod:
on *:input:*:{
  if ($regex($window($active).type,^(query|channel)$) && (!$regex($left($1,1),\/))) {
    say $+(«,$chr(160),$1-,$chr(160),»)
    haltdef
  }
}

L4roXyL 11 Ekim 2011 00:45
Tarih: 14-01-2009, 00:57

Bu kod #kanal kanalında voice verilen nicklerin host adreslerini kayıt eder ve #kanal@ kanalında !info komutunu uyguladığınızda bu liste kanala yansıtılır.
Not: Kod on text üzerine kuruludur. Dolayısıyla başkaları için !komut olarak uygulanabilir. Kendiniz için kullanacaksanız on input kullanabilirsiniz.

Kod:
on *:start:{
  if ($exists(voice.hash)) hmake voice | hload -i voice voice.hash
}
on *:voice:#kanal:{
  if ($nick != $me) {
    var %q = $+($address($vnick,2),%,$time,&,$date)
    hadd -m voice %q $nick
    hsave -i voice voice.hash
  }
}
on @*:text:!info *:#kanal@: {
  if ($hfind(voice,$2,0).data >= 2) {
    var %2 = $v1,%1 = 1
    msg # $2 rumuzunun voice girdileri:
    while (%1 <= %2) {
      var %d = $hfind(voice,$2,%1).data
      msg # $+(%1,-) Host: $gettok(%d,1,37) - Saat/tarih: $regsubex($gettok(%d,2,37),&,$chr(32))
      inc %1
    }
    else msg # $qt($nick) $2 rumuzu için kayıt bulunamadı.
  }
}


++ mIRCScripting.net hakkında kısaca:

mS; "Gayri resmi mIRC" kullanıcı ve tasarımcı topluluğudur.
2009 yılında kurulan mS; tasarımcı ve geliştiricileri bir araya getiren etkileşim ve iletişim sağlayan bir platformdur.
mS; tasarım, programlama, geliştirme, düzenleme vb. pek çok konu etrafında bir araya gelmiş "mIRC" meraklısı bir çok insan tarafından yaratılan içeriğiyle; kullanıcı dostu, özgün elit, nitelikli kişi ve konularla hizmet sunan mIRC Scripting platformudur.

Özgün içerikten onay almaksızın içeriği yaratan kullanıcılarımız tamamen yada kısmen sorumludur, aynı zamanda söz konusu içerik mS yetkilileri izni olmaksızın, kaynak gösterilse dahi(!) kopyalanamaz ve/ya paylaşılamaz.   Site/içerik hakkında görüş, öneri ve şikayetleriniz için sikayet[at]mircscripting[dot]net e-posta ve ya İletişim adresinden bizlere ulaştırabilirsiniz.



mIRC mIRC Orjinal mIRC İndir mIRC Download mIRC Tutorials mIRC Socket mIRC Commands mIRC Komutlar mIRC Yükle mIRC Dersler mIRC Hazır Kodlar mIRC Classentifier mIRC DLL mIRC Dialog mIRC IRC mIRC FTP mIRC Telnet mIRC Help
mIRC Yardım mIRC Iconlar mIRC Com Object mIRC Binary Files mIRC Picture Windows mIRC Unicode mIRC Forum mIRC Hazır Kodlar mIRC Kod mIRC Script mIRC File Handling mIRC Scripting Language mIRC Scripting Dili mIRC Scripting Info
mIRC Scripting Tutorials

Sayfa 2 Toplam 3 Sayfadan 1 2 3
Konuya ait 40 Mesajı başka Sayfada göster



User Alert System provided by Advanced User Tagging v3.1.3 (Lite) - vBulletin Mods & Addons Copyright © 2026 DragonByte Technologies Ltd. Runs best on HiVelocity Hosting.

1 2 13 14 16 17 18 19 21 22 23 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 49 50 51 52 54 55 56 57 58 59 60 61 62 63 67 68 69 70 71 72 73 74 75 76

SEO by vBSEO 3.6.1