mIRC Scripting
Sayfa 1 Toplam 3 Sayfadan 1 23
Konuya ait 40 Mesajı başka Sayfada göster

mIRC Scripting (https://www.mircscripting.net/)
-   Snippets - Parça kodlar (https://www.mircscripting.net/snippets-parca-kodlar/)
-   -   Yaptığım Tüm Yardımlar/Kodlar (https://www.mircscripting.net/snippets-parca-kodlar/537-yaptydhym-tuem-yardymlar-kodlar.html)

L4roXyL 07 Ekim 2011 12:15
Yaptığım Tüm Yardımlar/Kodlar
 
Tarih: 06-12-2007, 19:09

Sesli harfleri "*" karakteri olarak gösterme.
Kullanım: Reklam.txt içerisindeki kelimeler üzerinde işlev yapar.

Kod:
on @*:text:*:#:{
  var %s = 1,%ss = $lines(reklam.txt)
  while %s <= %ss {
    if $+(*,$read(reklam.txt,%s),*) iswm $1- {
      var %o = $remove($v1,*),%p = $regsub(%o,/(a|e|i|u|ü|o|ö|[A-Z])/gi,$chr(42)\1,%o)
      ban -k # $nick 2 Yasaklı kelime kullandınız: %o
    }
    inc %s
  }
}


İkinci kullanım:

Örneğin; //echo -: $ok(Nasılsınız?) yaptığında; N*s*ls*n*z? olarak dönecektir.

Kod:
alias ok {
  var %1 = $1-
  var %2 = $regsub(%1,/(a|e|i|u|ü|o|ö|ı)/gi,$chr(42)\1,%1)
  return %1
}

L4roXyL 07 Ekim 2011 12:18
Tarih: 06-12-2007, 20:21

Bu kod özele yazan nick kayıtlı değilse ve kufur.txt dosyasından herhangi bir kelimeyi kullandıysa, tüm kanallardan banlamak için kullanılır.

Kod:
on *:text:*:?: {
  inc -e $+(%,t,$nick)
  if $($+(%,t,$nick),2) == 1 {
    .enable #u
    .who $nick
  }
  else {
    var %1 = 1,%2 = $lines(kufur.txt)
    while %1 <= %2 {
      if $+(*,$read(kufur.txt,%1),*) iswm $1- && $hmatch(nick,$nick) {
        var %p = $nick
      }
      inc %1
    }
    var %s = 1,%ss = $comchan($me,0)
    while %s <= %ss {
      if $nick ison $comchan($me,%s) {
        ban -ku900 $comchan($me,%s) %p 2 BAN SEBEBİ.
      }
      inc %s
    }
  }
}
#u off
raw *:*: {
  if $numeric == 352 {
    if r !isincs $7 {
      haltdef
      hadd -m nick $6 1
    }
  }
  if $numeric == 315 {
    haltdef
    .disable #u
  }
}
#u end

L4roXyL 07 Ekim 2011 12:21
Tarih: 06-12-2007, 20:34

Kanal menüsünü sağ tıklayarak temizle.txt içerisindeki dosyayı kanala yansıtma.
Not: Kanal temizlemek için kullanılır.

Kod:
menu channel {
  Temizle:temizle #
}
alias temizle {
  var %u = 1,%s = $lines(temizle.txt)
  while %u <= %s {
    msg $1 $read(temizle.txt,%u)
    inc %u
  }
}

L4roXyL 07 Ekim 2011 12:26
Tarih: 07-12-2007, 17:37

Belirtilen kanala giren kullanıcıları, belirlenen kanallara random sajoin-lemek.

Kod:
on !*:join:#belirtilen-kanal:{
  var %q = #kanal1 #kanal2 #kanal3 #kanal4 #kanal5,%t = $calc($numtok(%q,32)+1)
  inc -e %r
  $iif(%r != %t,sajoin $nick $gettok(%q,%r,32),unset %r)
}

L4roXyL 07 Ekim 2011 12:31
Tarih: 05-12-2007, 16:50

i) Kufur.txt dosyası üzerinde kanal yazılan text-lere işlem yapmak.
ii) Dosyaya kelime eklemek.
iii) Dosyadan kelime silmek.
iiii) Dosyadaki kelimeleri listemek vs.


Kod:
;/kekle kelime
alias kekle {
  if $1 {
    if $read(kufur.txt,w,$1) {
      echo -at $1 kelimesi zaten listede.
      return
    }
    else {
      write kufur.txt $1
      echo -at $1 kelimesi listeye eklendi.
    }
  }
}

;/ksil kelime
alias ksil {
  if $1 {
    if !$read(kufur.txt,w,$1) {
      echo -st $1 kelimesi listede yok.
      return
    }
    else {
      write $+(-dl,$readn) kufur.txt
      echo -st $1 kelimesi kufur listesinden silindi.
    }
  }
}

;/klist
alias klist {
  var %s = 1,%ss = $lines(kufur.txt)
  while %s <= %ss {
    echo -a Kelime: $read(kufur.txt,%s)
    inc %s
  }
}

;Esas kod
on @*:text:*:#:{
  var %s = 1,%ss = $lines(kufur.txt)
  while %s <= %ss {
    if $+(*,$read(kufur.txt,%s),*) iswm $1- {
      ban -k # $nick 2 küfür yasak vs.
    }
    inc %s
  }
}

L4roXyL 07 Ekim 2011 12:39
Tarih: 08-12-2007, 21:15

Belirtilen kanalda kendi yazdığınız !sebeb [ip] kelimesi ilen belirtilen ip-i gzline/gline vb. listesinde arayıp, banlanma sebebini size/kanala yansıtacak kod.
Kullanım: !sebeb [ip-adresi]

Kod:
on *:input:#belirtilen-kanal:{
  if $1 == !sebeb && $2 {
    .enable #x
    set %ip $2
    stats g
  }
}
#x off
raw *:*:{
  if $numeric = 223 {
    haltdef
    var %& = $remove($3,@,*)
    if %ip == %& {
      hadd -m g $replace($7-,$chr(32),$chr(61))
    }
  }
  if $numeric = 219 {
    haltdef
    if !$hget(g) {
      msg #belirtilen-kanal %ip ip'i bulunamadı.
      return
    }
    else { 
      msg #belirtilen-kanal %ip ip'inin atılma sebebi; $replace($hget(g,1).item,$chr(61),$chr(32))
      hfree g
      disable #x
    }
  }
}
#x end

L4roXyL 07 Ekim 2011 12:43
Tarih: 09-12-2007, 00:25

MsnSONG.dll kullanarak sunucudaki kullanıcı sayısını /map komutu ile msn-ye yansıtmak.

Kod:
alias msnsong {
  var %dll MsnSong.dll
  .comreg %dll
  .comopen msn Msn.Write
  var %i $com(msn,WriteToMsn,1,bstr,$1-,bstr,$null,bstr,$null)
  .comreg -u %dll
  .comclose msn
}
raw 6:*:msnsong $2 user sayısı: $3

L4roXyL 07 Ekim 2011 13:19
Tarih: 20-01-2008, 00:25

Kanal text gönderirken text içerisinde kanalda bulunan bir nick varsa o nick bold/kalın olarak belirleme.

Kod:
on *:input:*: {
  if $left($1,1) != / {
    var %q 1
    while (%q <= $numtok($1-,32)) {
      if ($gettok($1-,%q,32) ison $active) {
        say $replace($1-,$v1,$+($chr(2),$v1,$chr(2)))
        break
      }
      inc %q
    }
    haltdef
  }
}

L4roXyL 07 Ekim 2011 13:24
Tarih: 05-01-2008, 14:35

Özelinizdeki (/query) nickin clone-si hakkında bilgi veren kod.

Kod:
on *:active:?: {
  if $ial($address($active,2),0) >= 2 {
    inc -e $+(%,p,$active)
    if $($+(%,p,$active),2) == 1 {
      var %1 1,%2
      while %1 <= $ial($address($active,2),0) {
        %2 = $addtok(%2,$gettok($ial($address($active,2),%1),1, 33 ),32)
        inc %1
      }
      echo $active %2 nickleri aynı hosta sahipler.
    }
  }
}

L4roXyL 07 Ekim 2011 13:28
Tarih: 05-01-2008, 01:08

Kanala giren guest takılı kullanıcılara işlev(uyarı, 2. uyarı ve ban) yapmak için hazırlamış olduğum bir kod.

Kod:
on *:join:#:$iif($nick == $me,.timerkntrl 0 60 guest #,$iif(guest* iswm $nick,$+(.timer,$v2) 1 30 msg # $+($chr(22),$v2,$chr(22)) nick değiştiriniz vs.))
alias guest {
  if $ialchan(Guest*,$1,0) >= 2 {
    var %t = 1,%y
    while %t <= $ialchan(Guest*,$1,0) {
      %y = $addtok(%y,$+($chr(22),$gettok($ialchan(Guest*,$1,%t),1,33),$chr(22)),32)
      $iif($hmatch(nick,$gettok($ialchan(Guest*,$1,%t),1,33)),hinc -m nick $gettok($ialchan(Guest*,$1,%t),1,33) 1,hadd -m nick $gettok($ialchan(Guest*,$1,%t),1,33) 1)
      if $hget(nick,$gettok($ialchan(Guest*,$1,%t),1,33)) >= 3 {
        ban -k $1 $gettok($ialchan(Guest*,$1,%t),1,33) 2 Sebeb.
        $+(.timer,$gettok($ialchan(Guest*,$1,%t),1,33)) off
        hdel -s nick $gettok($ialchan(Guest*,$1,%t),1,33)
      }
      inc %t
    }
    msg $1 %y nick değişiniz vs.
  }
}

L4roXyL 07 Ekim 2011 13:34
Tarih: 05-01-2008, 15:05

Gelen noticeleri, snoticeleri ve rumuzunun geçtiği mesajları(kanal ayrı, özel ayrı) ayrı pencerelerde gösteren kodlar.

Kod:
on ^*:snotice:*:{
 $iif(!$window(@duyuru),window -nCBas @duyuru)
 echo 5 @duyuru SNOTICE: $1-
}
on ^*:notice:*:?:{
 $iif(!$window(@duyuru),window -nCBas @duyuru)
 echo 5 @duyuru Servis: $nick - Mesajı: $1-
}
on *:text:$($+(*,$me,*)):?: {
  if $active != $nick {
    $iif(!$window(@seslenme),window -nCBas @seslenme)
    echo 5 @seslenme Nick: $nick - Mesajı: $1-
    echo -ate Nick: $nick - Mesajı: $1-
  }
}
on *:text:$($+(*,$me,*)):#: {
  if $active != # {
    $iif(!$window(@seslenme),window -nCBas @seslenme)
    echo 5 @seslenme Kanal: # - Nick: $nick - Mesajı: $1-
    echo -ate Kanal: # - Nick: $nick - Mesajı: $1-
  }
}

L4roXyL 07 Ekim 2011 13:36
Tarih: 05-01-2008, 00:17

Size whois çeken kullanıcıları aynı bir pencerede(-l) listeleyen(aline) kod.

Kod:
on *:snotice:*did a /whois on you*: {
  inc %1 
  $iif(!$window(@whois),window -lCb @whois,aline 2 @whois $+(%1,-) $2 whois çekti.)
}

L4roXyL 07 Ekim 2011 13:39
Tarih: 05-01-2008, 15:13

Tüm kanallardaki flaglarınızı(a,o,v,h,q vb.) larınızı geri almak için yazmış olduğum bir kod.
Kullanım: /opall

Kod:
alias opall {
  var %s = 1
  while %s <= $comchan($me,0) {
    mode $comchan($me,%s) -aqhvo $str($+($me,$chr(32)),5)
    inc %s
  }
}

L4roXyL 07 Ekim 2011 13:45
Tarih: 05-01-2008, 16:12

Belitilen kanala giren kullanıcıların IP numaralarını işleme alarak, daha önce sunucuya girip/girmediği gösteren detaylı bir kod.

Kod:
on *:join:#belirtilen-kanal:userip $nick
alias iptara {
  if $hget(kayıt) {
    var %o = 1
    while %o <= $hget(kayıt,0).item {
      if $gettok($hget(kayıt,%o).item,2,189) == $1 && $gettok($hget(kayıt,%o).item,1,189) != $2 {
        $iif(!$window(@sonuc),window -nCbsa @sonuc)
        echo -te @sonuc Bilgi: $gettok($hget(kayıt,%o).item,2,189) IP adresin'den daha önce; $gettok($hget(kayıt,%o).item,1,189) nick'i ile giriş yapıldı.
      }
      inc %o
    }
  }
}
raw *:*: {
  haltdef
  if ($numeric = 340) {
    set %ip $gettok($2,2,64)
    who +h $gettok($2,2,64)
    hadd -m kayıt $+($gettok($2,1,61),½,$gettok($2,2,64))
    iptara $gettok($2,2,64) $gettok($2,1,61)
  }
  if ($numeric = 352) {
    hadd -m nick $6 1
  }
  if ($numeric = 315) {
    var %& = 1,%&&
    while %& <= $hget(nick,0).item {
      %&& = $addtok(%&&,$hget(nick,%&).item,32)
      inc %&
    }
    $iif(!$window(@IP),window -nCbsa @IP)
    echo -t @IP Bilgi: %ip adresin'den bağlantı kuranlar: %&&
    unset %ip
    hfree nick
  }
}

L4roXyL 07 Ekim 2011 13:49
Tarih: 05-01-2008, 20:29

Belirtilen kanala giriş yaptığınızda dosya.txt dosyasından mesajları 15 dakikada bir sırayla göndermek için yazmış olduğum bir kod.

Kod:
on me:join:#belirtilen-kanal:.timer 0 180 textsnd #
alias textsnd {
  if $lines(dosya.txt) = %t {
    unset %t
    inc %t
  }
  else inc %t
  msg $1 $read(dosya.txt,%t)
}

L4roXyL 07 Ekim 2011 13:57
Tarih: 06-01-2008, 17:03

/exit yazdığınızda belirlediğiniz mesajı /ame olarak attıktan sonra çıkış yapmak için yazdığım bir kod.

Kod:
alias exit {
  inc -e %e
  if (%e = 1 && $status = connected) {
    ame mesajın
  }
  else exit -n
}

L4roXyL 07 Ekim 2011 14:01
Tarih: 05-01-2008, 23:55

Socket bot için sunucuya giren ve belirtilen idente sahip kullanıcıyı belirtilen kanala /sajoin-lemek için yazmış olduğum bir kod.

Kod:
if ($2 = notice && *Client connecting* iswm $3-) {
  if ($remove($gettok($13,1,64),$chr(40)) = belirtilen-ident) {
    sockwrite -n socket-ismi sajoin $12 #belirtilen-kanal
  }
}

L4roXyL 07 Ekim 2011 14:10
Tarih: 06-01-2008, 19:44

Kanal belirlediğiniz flood saldırısında, kanalı belirlediğiniz süre ile +m moduna alıp, temizle.mrc dosyasındaki verilerle kanalı temizleyip tekrar kanalaı açmak için yazmış olduğum bir kod.

Kod:
alias -l fld {
  hinc $+(-mu,$1) fld $+($3,½,$4,$encode($5)) 1
  if ($hget(fld,$+($3,½,$4,$encode($5))) >= $2) return $true
  else return $false
}
alias temizle {
  var %t 1
  while %t <= $lines(temizle.mrc) {
    msg $1 $read(temizle.mrc,%t)
    inc %t
  }
}
on @*:text:*:#: {
  if $nick isreg # && $fld(10,3,#,$nick,$1-) {
    ban -k # $nick 2 sebeb.
    mode # +m
    temizle #
    msg # Kanal güvenlik amaçlı 20 sn vs.
    if !$timer($+(#,½,fld)) {
      $+(.timer,½,#) 1 20 mode # -m
      .timer 1 21 msg # Kanal açıldı.
    }
  }
}
/fld alias'ının kullanımı; $fld(saniye,limit,#kanal,text-own,mesaj)
Ben örnek olarak; 10 saniye içerisin'de, aynı text 3 defa tekrar edilirse, gördüğünüz işlevleri sırası ile gerçekleştirir.

Eğer aynı yazının tekrar'ı değilde, belirlediğim saniye içerisin'de belirlediğim satır limit'i aşılırsa(hızlı text) işlev yapmak istiyorum diyorsan;
/fld alias'ını aşşağıdaki şekilde değiştir;

Kod:
alias -l fld {
 hinc $+(-mu,$1) fld $+($3,½,$4) 1
 if ($hget(fld,$+($3,½,$4)) >= $2) return $true
 else return $false
}


Ve kullanım şeklini verdiğim şekilde yap; $fld(saniye,limit,#kanal,text-own)

Örneğin; $fld(10,5,#,$nick)
10 saniye içerisinde, 5 satır text gönderen'e işlev yapar. Kanal'ı temizler vs.

L4roXyL 07 Ekim 2011 14:16
Tarih: 25-10-2007, 20:08

Bu kod kanal veya özel loglarını aramak/okumak vb. işlemler için yazılmış detaylı bir snippet-dır.


Kod:
menu channel {
  Loglar menüsü
  .# logu:kanal #
  .Özel logları:falan $$?="Log'unu okumak istediginiz nick'i giriniz:"
}
alias falan {
  if $findfile($logdir,$+($1,*),0) >= 1 {
    var %1 = $v1
    $iif($input(Aradığınız nick için %1 adet veri bulundu açmak istiyormusunuz?,w) == $false,halt)
    var %2 = 1,%3 = $findfile($logdir,$+($1,*),0)
    while %2 <= %3 { run $findfile($logdir,$+($1,*),%2) | inc %2 }
  }
  else {
    var %/ = $1,%½ = $left($1,1)
    $iif($input(Aradığınız %/ nick'i için uygun kayıt bulunamadı. %½ harfi ile başlıyan loglar listelensinmi?,w) == $false,halt)
    echo -at $left($1,1) ile başlıyan loglar sıralanıyor.
    echo -at $findfile($logdir,$+($left($1,1),*),0,echo -at $gettok($1-,$numtok($1-,92),92))
  }
}
alias kanal {
  if $findfile($logdir,$+($1,*),0) >= 1 {
    var %1 = $v1, %% = $1
    $iif($input(Aradığınız %% kanal'ı için %1 adet veri bulundu açmak istiyormusunuz?,w) == $false,halt)
    var %2 = 1,%3 = $findfile($logdir,$+($1,*),0)
    while %2 <= %3 {
      run $findfile($logdir,$+($1,*),%2)
      inc %2
    }
  }
  else { 
    var %& = $1
    $input(%& kanal'ı için herhangi bir kayıt bulunamadı,ohud,UYARI,)
  }
}

L4roXyL 07 Ekim 2011 14:23
Tarih: 06-01-2008, 23:13

Bu kod belirtilen kanala(sağ tıklayın popups bölümünde var) logları okumanıza yarar.

Kod:
menu channel {
  # kanal log'u:searchlog # $gettok($server,2-,46)
}
alias searchlog {
  if ($findfile($logdir,$+($1,.,$2,*),0) = 0) $iif($input($1 kanal' için log bulunamadı.,ohud,uyarı) = $true,return,return)
  run $findfile($logdir,$+($1,.,$2,*),1)
}

L4roXyL 07 Ekim 2011 14:30
Tarih: 07-01-2008, 18:42

Bu kod belirtilen kanaldaki tüm kullanıcılara kontrol mesajı yollar. Eğer 10 saniye içerisinde herhangi bir kullanıcı mesaja cevap verirse kanaldan banlayacaktır.
Kodu kullanmak için, belirtilen kanalın client editbox kutusuna /kontrol yazmanız yeterli olacaktır.

Kod:
alias kontrol {
  write -c kontrol.txt
  set -eu10 %k $active
  var %1 = 1,%v1
  while $nick(%k,%1) {
    %v1 = $v1
    if %v1 != $me {
      .msg %v1 Kontrol mesajıdır.
      write kontrol.txt %v1
    }
    inc %1
  }
}
on *:text:*:?:if (%k && $nick ison %k && $read(kontrol.txt,w,$nick)) ban -k %k $nick 2 sebeb.

L4roXyL 07 Ekim 2011 14:36
Tarih: 07-01-2008, 20:43

Bu kod #help - #yardım kanalına giren kullanıcının host adresine bakarak, admin, ircop vb. kişiler dışındaki kişilere +v(voice) verip mesaj göndermek için yazılmıştır.

Kod:
on !*:join:#help,#yardım: {
  if (!$regex($gettok($address($nick,2),2,64),/network|admin|ircop/i)) {
    mode # +v $nick
    msg # $nick mesajın.
  }
}
Not: | operatörü ile daha fazla host ekleyebilirsiniz.

L4roXyL 07 Ekim 2011 14:40
Tarih: 09-01-2008, 15:03

Bu kod sunucuya giren kullanıcının ident, nick ve fullname-si birbirinin aynısı ise sunucudan gline ile uzaklaştırmak için yazılmıştır.

Kod:
on *:snotice:*client connect*: {
  if ($left($9,-2) = $remove($gettok($10,1,64),$chr(40)) && $remove($11,[,]) = $left($9,-2)) {
    gline $9 sebeb.
  }
}

L4roXyL 07 Ekim 2011 14:46
Tarih: 08-01-2008, 22:12

Bu kod herhangi bir kanala girdiğinizde eğer 2 saniye içerisinde özelinize yazan olursa, bulunmuş olduğunuz tüm kanallardan banlamak için yazılmıştır.

Kod:
on *:join:#:if ($nick = $me) inc -eu2 %k
on *:text:*:?: {
  if %k {
    var %1 = $1-,%2 = 1
    while $comchan($nick,%2) {
      ban -k $v1 $nick 2 Yasaklı kelime: %1
      inc %2
    }
  }
}

L4roXyL 07 Ekim 2011 14:54
Tarih: 10-01-2008, 04:30

Bu kod belirtilen saniyede belirtilen sayıda aynı text kanala gönderilirse o text-i 10 dakikalığına spamfilter listesine eklemenize yarar.

Kod:
on *:text:*:#: {
  if $nick isreg # {
    hinc -mu3 fln $+(#,½,$nick,$encode($1-)) 1
    if ($hget(fln,$+(#,½,$nick,$encode($1-))) >= 5) {
      spamfilter add cpnNa gzline 10m - $1-
      hdel fln $+(#,½,$nick,$encode($1-))
    }
  }
}
3 olan yer saniye, 5 olan yer limittir. Değiştirebilirsiniz.

L4roXyL 07 Ekim 2011 15:07
Tarih: 10-01-2008, 04:30

Bu kod sunucuya aynı nick üzerinden belirtilen sürede belirtilen sayıdan fazla giren kullanıcıların hepsini sunucudan uzaklaştırır.

Kod:
on *:snotice:*client connect*: {
  hadd -mu60 nick $9 1
  if $hget(nick,0).item >= 10 {
    var %s = 1,%ss = $hget(nick,0).item
    while %s <= %ss {
      gline $hget(nick,%s).item :sebeb.
      inc %s
    }
  }
}
60 saniye, 10 ise limittir. Değiştirebilirsiniz.

L4roXyL 07 Ekim 2011 15:18
Tarih: 10-01-2008, 04:30

Bu kod 1 saniye içerisinde sunucudan 10 kişi veya fazlası çıkarsa, o nicklere ait IP-lerin hepsini sunucudan banlayacaktır.

Kod:
on *:snotice:*client exiting*: {
  hadd -mu1 ip $remove($gettok($7,2,64),$chr(41)) 1
  if $hget(ip,0).item >= 10 {
    var %k = 1,%kk = $hget(ip,0).item
    while %k <= %kk {
      zline $+(*@,$hget(ip,%k).item) :sebeb
      inc %k
    }
  }
}
1 kısmı saniye, 10 kısmı limittir. Değiştirebilirsiniz.

L4roXyL 07 Ekim 2011 15:23
Tarih: 10-01-2008, 17:15

Bu kod belirtilen kanaldaki yetkisiz(op, su-op, voice, halfop vs.) tüm nicklerin özeline away kontrol mesajı atmanıza olanak sağlar. Kodu çalıştırmak için, kanal client penceresine /kontrolaway yazmanız yeterli olacaktır.

Kod:
alias kontrolaway {
  if $left($active,1) = $chr(35) {
    var %s = 1
    while $nick($active,%s) {
      if $count($nick($active,%s).pnick,@,&,~,+,%,.) = 0 {
        .msg $nick($active,%s) Away Kontrol mesajıdır.
      }
      inc %s
    }
  }
}

L4roXyL 07 Ekim 2011 15:30
Tarih: 19-01-2008, 00:44

Bu kod varolan tüm logları mIRC Custom(@log) penceresinde list şeklinde listelemenize, okumanıza ve silmenize yarayacaktır. Çok hızlı çalışmakla beraber basit bir arayüze sahip işlem yapmak isterseniz, gayet uygundur.

Kod kullanımı: /logoku
Belirtilen logu açmak için, listdeki log-lara çift tıklayın.
Sectiğiniz logu silmek için listedeki loga tıklayıp, DEL tuşuna basmanız yeterli olacaktır.


Kod:
menu @log {
  dclick:$iif($mouse.lb,logs $active $1,return)
}
on *:keydown:@log:46: {
  var %1 = $sline(@log,1),%2 = $sline(@log,1).ln
  if (%1) $iif($input(%1 log'unu silmek istediğiniz'den eminmisiniz?,y,Uyarı) = $true,sil %1 %2,halt)
}
alias logoku {
  $iif(!$window(@Log),window -aCl15 @Log)
  if $findfile($logdir,*,0) != 0 {
    $findfile($logdir,*,0,aline -l @Log $nopath($1-))
  }
}
alias logs {
  var %1 = 1,%2 = $lines($+($logdir,$sline(@log,1))),%3 = $sline(@log,1)
  loadbuf -rp @log $shortfn($logdir $+ %3)
}
alias sil .remove -b $shortfn($+($logdir,$1)) | window -c @log | logoku

L4roXyL 07 Ekim 2011 15:38
Tarih: 13-01-2008, 18:55

Bu kod #help kanalında voice verdiğiniz bir kullanıcı eğer 60 saniye içerisinde herhangi bir veri yazmazsa kullanıcıyı kanaldan banlar.

Kod:
on *:voice:#help: {
  if ($nick == $me) $+(.timer,$vnick,_voice) 1 60 ban -k # $vnick 2 sebeb.
}
on *:text:*:#help: {
  if ($timer($nick $+ _voice)) $+(.timer,$v1) off
}


60 kısmı saniyedir. Değiştirebilirsiniz.

L4roXyL 07 Ekim 2011 15:42
Tarih: 14-01-2008, 00:02

Bu kod sunucuya giren kullanıcının IP adresine bakarak clone/klon taraması yapar ve bu tarama sonuçlarını /echo komutu ile aktif ekrana yansıtır.


Kod:
on *:snotice:*: {
  if *client connect* iswm $1- {
    var %s = $remove($gettok($10,2,64),$chr(41)) | hadd -m ip $+($9,½,%s)
    if $hmatch(ip,$+(*,%s),0) >= 2 {
      var %q 1,%qq,%qqq = $gettok($hmatch(ip,$+(*,%s),1),2,189)
      while %q <= $hmatch(ip,$+(*,%s),0) {
      %qq = $addtok(%qq,$gettok($hmatch(ip,$+(*,%s),%q),1,189),44)
      inc %q
    }
    echo -at Bilgi: %qqq adresiden bağlantı kuranlar: %qq  }
  }
  if *client exiting* iswm $1- {
    if ($hmatch(ip,$+(*,$remove($gettok($7,2,64),$chr(41))))) hdel ip $v1
  }
}

L4roXyL 07 Ekim 2011 15:46
Tarih: 14-01-2008, 14:37

Bu kod sunucuya giren kullanıcıya /who çeker ve eğer fullname kısmında dosya.txt dosyasındaki kelimelerden biri varsa, sunucudan uzaklaştırır. Yani kısacası fullname-de reklam veya yasaklı kelime arayan koddur.

Kod:
raw 352:*:kontrol2 $9- $6
on *:snotice:*client connect*:who $9
alias kontrol2 {
  var %1 = 1
  while $read(dosya.txt,%1) {
    if $regex($1,/ $+ $v1 $+ /i) {
      zline $2 :ban sebebi.
      return $true
    }
    inc %1
  }
  return $false
}

L4roXyL 07 Ekim 2011 15:51
Tarih: 14-01-2008, 15:59

Bu kod belirtilen kanalda op/sop/halpfop vs. olan kullanıcıları belirlediğiniz diğer kanala otomatik /sajoin-lemeye yarayan koddur.

Kod:
on *:rawmode:#belirtilen-kanal: {
  if $left($1,1) = $chr(43) && $regex($right($1,-1),a|o|h) {
    sajoin $2 #belirtilen-kanal2
  }
}

L4roXyL 07 Ekim 2011 16:01
Tarih: 14-01-2008, 18:04

Bu kod picture window ile yazılmış olup, script açılış sayacı işlemi görmektedir.


Kod:
on *:start:start
alias start {
  .timer 1 3 window -c @start | window -c @start | inc %x | window -pdhBCk0 +d @start 0 0 140 45
  drawrect -r @start $rgb(150,150,150) 100 0 0 140 45 | drawrect -r @start $rgb(0,0,0) 3 0 0 140 45
  drawtext -r @start $rgb(0,0,0) Tahoma 11 30 14 $iif(%x == 1,Script ilk defa açıldı.,Script %x kere açıldı.)
  drawtext -r @start $rgb(255,255,255) Tahoma 13 130 0 x | window -a @start
}
menu @start {
  sclick:if ($mouse.x >= 130) window -c @start
}

L4roXyL 07 Ekim 2011 16:10
Tarih: 19-01-2008, 23:01

Bu kod belirtilen kanala giren kayıtlı kullanıcılara belirlediğiniz mesajı gönderir.

Kod:
on !*:join:#belirtilen-kanal:.enable #q | who $nick | set %_k #
#q off
raw *:*: {
  if ($numeric = 352) {
    if (r isin $7 && $6 ison %_k) .msg $6 %_k belirtilen mesaj.
  }
  if ($numeric = 315) { .disable #q | unset %_k }
}
#q end

L4roXyL 07 Ekim 2011 16:22
Tarih: 22-01-2008, 20:21

Bu kod herhangi bir kanal penceresinde /tara komutunu uyguladığınızda, badnick.txt dosyasındaki verileri kanal rumuzlarının içinde tek tek arar. Arama işlemi sırasında yakalanan nickleri kanaldan uzaklaştırır ve işlem tamamlandığında kaç adet badnick-in atıldığını size yansıtır.

Kod:
alias -l bn {
  var %s = 1
  while ($read(badnick.txt,%s)) {
    if $+(*,$v1,*) iswm $2 {
      hinc -m bn nk 1
      ban -k $1 $2 2 sebeb.
      break
    }

    inc %s
  }
}
alias tara {
  $iif($hget(bn),hfree bn)
  echo -ae Badnick taraması başlatıldı.
  var %1 = 1
  while ($nick($active,%1)) {
    bn $active $v1
    inc %1
  }
  echo -ae $active Toplam $+($chr(40),$iif(!$hget(bn,nk),0,$hget(bn,nk)),$chr(41)) badnick atıldı.
}

L4roXyL 07 Ekim 2011 16:40
Tarih: 22-01-2008, 01:38

Bu kod, belirtilen kanala text gönderen kullanıcının gönderdiği satır sayısı, belirtilen satır limiti miktarına ulaştığı zaman voice(+) vermek için kullanılır. Bir nevi ödüllendir gibi yani. Kodu geliştirebilirsiniz. Mantık gayet açıktır.

Kod:
on *:text:*:#belirtilen-kanal:{
  if (!$count($nick(#,$nick).pnick,@,&,%,~,+)) {
    hinc -m txt $+(#,½,$nick) 1
    if ($hget(txt,$+(#,½,$nick)) >= 100) {
      mode # +v $nick
      msg # $+($nick,:) muhabbet ortamı sağladın vs.
    }
  }
}
100 olarak belirtilen yer satır sayısıdır.

L4roXyL 07 Ekim 2011 16:46
Tarih: 27-01-2008, 15:36

Bu kod notify listesindeki kişilerin haraketlerini takip etmenize yarar. Bu haraketleri @notify penceresinde gösterir.

Kod:
on ^*:notify: {
  $iif(!$window(@notify),window -aCk0 @notify)
  echo -t @notify => $nick giriş yaptı.
  haltdef
}
on ^*:unotify: {
  $iif(!$window(@notify),window -aCk0 @notify)
  echo -t @notify <= $nick çıkış yaptı.
  haltdef
}

L4roXyL 07 Ekim 2011 16:54
Tarih: 31-01-2008, 18:45

Bu kod belirtilen kullanıcıya(kişinin penceresinde uygulanır) belirtilen dosyayı($2) göndermeye yarayacaktır.
Kodu kullanma şekli: !gönder dosya-adı.uzantısı

Kod:
alias yasaklılar {
  if ($dccignore) var %1 = 1
  while $dccignore(%1) {
    echo -a $+(%1,-) $v1
    inc %1
  }
}
on *:input:?: {
  if ($regex($1,/^!gönder$/i) && $2) {
    dcc passive off
    dcc trust $nick
    $iif($findfile(C:\,$2,0) >= 1,dcc send $active $shortfn($findfile(C:\,$2,1)))
  }
}
Not: Kodu uygulamadan önce, /yasaklılar yaparak yasaklı listesini kontrol ediniz.

L4roXyL 07 Ekim 2011 16:57
Tarih: 31-01-2008, 19:02

Bu kod belirtilen dosyayı mIRC Custom penceresinde açmanıza/okumanıza yarar.
Kullanım şekli: /oku dosya-adı.uzantısı

Kod:
alias oku {
    if ($1) window -Cak0 $+(@,$1)
    loadbuf -rp $+(@,$1) $qt($1)
}


++ mIRCScripting.net hakkında kısaca:

mS; "Gayri resmi mIRC" kullanıcı ve tasarımcı topluluğudur.
2009 yılında kurulan mS; tasarımcı ve geliştiricileri bir araya getiren etkileşim ve iletişim sağlayan bir platformdur.
mS; tasarım, programlama, geliştirme, düzenleme vb. pek çok konu etrafında bir araya gelmiş "mIRC" meraklısı bir çok insan tarafından yaratılan içeriğiyle; kullanıcı dostu, özgün elit, nitelikli kişi ve konularla hizmet sunan mIRC Scripting platformudur.

Özgün içerikten onay almaksızın içeriği yaratan kullanıcılarımız tamamen yada kısmen sorumludur, aynı zamanda söz konusu içerik mS yetkilileri izni olmaksızın, kaynak gösterilse dahi(!) kopyalanamaz ve/ya paylaşılamaz.   Site/içerik hakkında görüş, öneri ve şikayetleriniz için sikayet[at]mircscripting[dot]net e-posta ve ya İletişim adresinden bizlere ulaştırabilirsiniz.



mIRC mIRC Orjinal mIRC İndir mIRC Download mIRC Tutorials mIRC Socket mIRC Commands mIRC Komutlar mIRC Yükle mIRC Dersler mIRC Hazır Kodlar mIRC Classentifier mIRC DLL mIRC Dialog mIRC IRC mIRC FTP mIRC Telnet mIRC Help
mIRC Yardım mIRC Iconlar mIRC Com Object mIRC Binary Files mIRC Picture Windows mIRC Unicode mIRC Forum mIRC Hazır Kodlar mIRC Kod mIRC Script mIRC File Handling mIRC Scripting Language mIRC Scripting Dili mIRC Scripting Info
mIRC Scripting Tutorials

Sayfa 1 Toplam 3 Sayfadan 1 23
Konuya ait 40 Mesajı başka Sayfada göster



User Alert System provided by Advanced User Tagging v3.1.3 (Lite) - vBulletin Mods & Addons Copyright © 2026 DragonByte Technologies Ltd. Runs best on HiVelocity Hosting.

1 2 13 14 16 17 18 19 21 22 23 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 49 50 51 52 54 55 56 57 58 59 60 61 62 63 67 68 69 70 71 72 73 74 75 76

SEO by vBSEO 3.6.1