mIRC Scripting
Sayfa 3 Toplam 3 Sayfadan 12 3
Konuya ait 40 Mesajı başka Sayfada göster

mIRC Scripting (https://www.mircscripting.net/)
-   Snippets - Parça kodlar (https://www.mircscripting.net/snippets-parca-kodlar/)
-   -   Yaptığım Tüm Yardımlar/Kodlar (https://www.mircscripting.net/snippets-parca-kodlar/537-yaptydhym-tuem-yardymlar-kodlar.html)

L4roXyL 11 Ekim 2011 00:48
Tarih: 14-01-2009, 01:19

Bu kod sunucuya giren çıkan kullanıcıları @join-part penceresinde göstermeye yarar.

Kod:
on *:snotice:*:{
  if ($regex($1-,/client (connecting|exiting:)/i)) {
    var %s = $regml(1)
    if (!$window(@JOIN-PART)) window -aCk0 @join-part
    echo -t @join-part $iif(%s = connecting,Giriş: $9-10,$iif(%s = exiting:,Çıkış: $6-7))
  }
}

L4roXyL 11 Ekim 2011 00:53
Tarih: 15-01-2009, 08:26

Bu kod herhangi bir kanaldan başkası tarafından kick-lendiğinizde sounds klasöründeki kick.wav dosyasını çalmanıza ve baloncuk uyarısı almanızı sağlar.
Not: Baloncuk uyarısı(/tips - $tip) mIRC 6.31 sürümünden sonra geçerlidir.

Kod:
on *:kick:#:{
  if ($knick == $me && $nick != $me) {
    .splay -w $mircdirsounds\kick.wav
    noop $tip(kick,Kicklendiniz.,# kanalında $nick tarafından kicklendiniz.,8,,,,$window(#).wid)
  }
}

L4roXyL 11 Ekim 2011 00:56
Tarih: 15-01-2009, 08:26

Bu kod kanal veya özelde herhangi birisi sizin nickinizi yazdığında sounds klasöründeki connect.wav dosyasının çalmasını sağlar ve /echo ile aktif ekrana uyarı verir.

Kod:
on *:text:$($+(*,$me,*)):*:{
  var %e = echo -aet
  .splay -w $mircdirsounds\connect.wav
  if (#) {
    $iif($active != #,%e INFO: $+($nick,.) # kanalından size seslendi: $qt($1-))
  }
  else $iif($active != $nick,%e $nick özelden size seslendi: $qt($1-))
}

L4roXyL 11 Ekim 2011 01:01
Tarih: 15-01-2009, 08:59

Bu kod /gir şeklinde uygulandığında list-de çıkan tüm kanallara girmenize, /cık şeklinde uygulandığında #operhelp ve #help kanalları haric tüm kanallardan çıkmanıza yarar.

Kod:
alias gir set %jp join | .enable #x | list
alias cık set %jp part | .enable #x | list
#x off
raw *:*:{
  if ($regex($numeric,^(32[2-3])$)) {
    var %: = $regml(1)
    $iif(%: == 322,$iif(%jp == join,%jp $2,$iif(!$regex($2,/^(#operhelp|#help)$/i),%jp $2)),$iif(%: == 323,.disable #x))
  }
}
#x end

L4roXyL 11 Ekim 2011 01:10
Tarih: 15-01-2009, 09:45

Bu kod bir kanaldan diğer bir kanala belirtilen sayıdaki kullanıcı taşımak için kullanılır. Gayet gelişmiş bir koddur.
Kullanım şekli: /mjoin #aktarılacak-kanal #aktarılan-kanal <kullanıcı-sayısı>
Not: <kullanıcı-sayısı> kısmı boş veya sallamasyon bir sayı yazılırsa tüm userları çekcektir.

Kod:
alias mjoin {
  if ($regex($1,/^#(\w)/i) && $regex($2,/^#(\w)/i)) {
    var %1 = 1,%2 = $iif($iif($nick($1,0) >= $3,$3),$3,$nick($1,0))
    while (%1 <= %2) {
      $iif($nick($1,%1) !ison $2,sajoin $nick($1,%1) $2)
      inc %1
    }
  }
  else echo $color(info) -eat * /mjoin: Hatalı kullanım: /mjoin #INchan #OUTchan <number>
}

L4roXyL 11 Ekim 2011 01:23
Tarih: 19-01-2009, 23:03

Bu kod kanala giren rumuz içerisinde herhangi bir karakter 3 adet veya fazlası tekrar edilmişse kanaldan uzaklaştırmaya yarar.
Not: {3} kısmından limiti değiştirebilirsiniz.

Kod:
on !*:join:#:{
  if ($regex($nick,/(.+?)\1{3}/)) {
    ban -k # $nick 2 rumuzunuzda, $qt($regml(1)) karakterinden 7+ mevcut olduğundan uzaklaştırıldın vs.
  }
}

L4roXyL 11 Ekim 2011 01:29
Tarih: 07-07-2009, 17:23

Bu kod belirtilen kanal veya özel penceresine belirtilen dosyadaki satırları belirtilen saniye-de bir satır olmak kaydı ile yansıtmanıza yarar.
Kullanım şekli: /rfile #kanal|özel-pencere dosya.txt <saniye>
Örnek: /rfile #deneme deneme.txt 5
Açıklama: #deneme kanalına deneme.txt satılar 5 saniyede bir sırasıyla gönderilecektir.

Kod:
alias rfile {
  if ($regex(rfile,$1,^(-(r|p))$) && $timer(rfile)) {
    .timerrfile $regml(rfile,1)
    return
  }
  if ($2 && $3) {
    $iif(!$fopen(rfile),.fopen rfile $2)
    .timerrfile 0 $3 $!iif($fopen(rfile).eof,.fseek -l rfile 1) $(|) .msg $1 $!fread(rfile)
  }
}

L4roXyL 11 Ekim 2011 01:33
Tarih: 08-07-2009, 01:39

Bu kod scriptizi açtığınızda @bilgi penceresinde nick, yedek nick, IP adresi vb. bilgilerinizi görmenize olanak sağlar.

Kod:
on *:start: {
  if (!$window(@bilgi)) window -ak0 @bilgi
  var %e = echo 4 @bilgi,%c = $+($chr(3),1),%s = $token($readini($nopath($mircini),mIRC,host),2,58)
  %e Server: %c $+ %s
  %e Aktif $+(nick,:,%c,$chr(32),$iif($me,$v1,Girilmemiş.))
  %e Yedek $+(nick,:,%c,$chr(32),$iif($anick,$v1,Girilmemiş.))
  %e IP $+(adresi,:,%c,$chr(32),$ip)
  %e $+(Tarih/saat,:,%c,$chr(32),$date - $time)
}

L4roXyL 11 Ekim 2011 01:37
Tarih: 08-07-2009, 13:34

Bu kod dosya.txt içerisindeki kelimelerden biri kanala gönderildiğinde aktif ekranda /echo ile uyarı almak için kullanılır.

Kod:
on *:text:*:#:{
  var %1 = 1,%v1
  while ($read(dosya.txt,%1)) {
    %v1 = $v1
    if ($regex($1-,%v1)) {
      echo -caet action $nick # kanalında belirlediğiniz $+(kelimelerden,$chr(40),%v1,$chr(41)) birini kullandı.
      break
    }
    inc %1
  }
}

L4roXyL 11 Ekim 2011 01:41
Tarih: 10-07-2009, 23:41

Bu kod sunucuya giren kullanıcılara bad.txt dosyası içerisindeki kelimeleri tarayarak badnick kontolü yaparak, bulunan badnick-in rumuzunu user[random-sayı] şeklinde değiştirir.
Not: Bu kodu kullanabilmek için /os raw svsnick komutunu kullanabilmeniz gerekmektedir.

Kod:
on *:snotice:*client connect*:{
  var %1 = 1
  while ($read(bad.txt,%1)) {
    if ($regex($9,/ $+ $v1 $+ /i)) {
      inc %* 1
      os raw svsnick $9 $+(user,%*,$r(0,999)) 0:0
      break
    }
    inc %1
  }
}

L4roXyL 11 Ekim 2011 01:46
Tarih: 18-07-2009, 03:59

Bu kod herhangi bir kanalda "@,&,%,~" prefixlerine sahip olan kişilerin !banla <rumuz> <sebeb> şeklindeki komutu kullanarak belirtilen kullanıcıyı tüm kanallardan banlamanıza olanak sağlar.

Kod:
on *:text:!banla &:#:{
  if ($2 ison # && $regex($nick(#,$nick).pnick,[@&~%])) {
    var %1 = 1,%v1
    while ($comchan($2,%1)) {
      %v1 = $v1
      if ($regex($nick(%v1,$me).pnick,[@&~%])) {
        ban -k %v1 $2 2 BAN SEBEBİ.
      }
      inc %1
    }
  }
}

L4roXyL 11 Ekim 2011 01:50
Tarih: 20-12-2009, 16:10

Bu kod kanala giren kullanıcının rumuzunda dosya.txt içerisindeki kelimelerden tarama yaparak badnick olup olmadığını kontrol eder. Sonuç doğru dönerse kişi kanaldan uzaklaştırılır ve banlanan kaçıncı kişi olduğu mesajda gösterilir.

Kod:
on !*:join:#:{
  var %1 = 1
  while ($read(dosya.txt,%1)) {
    if ($v1 isin $nick) {
      inc %_bnick
      ban -k # $nick 2 badnick tespiti yapılan: %_bnick $+ . kişisin.
      break
    }
    inc %1
  }
}

L4roXyL 11 Ekim 2011 01:52
Tarih: 25-12-2009, 02:29

Bu kod kanala giren kullanıcıya kanala giren kaçıncı kişi olduğu bilgisini notice olarak sizin tarafınızdan bildirir.

Kod:
on !*:join:#:{
  inc $+(%,#,join)
  notice $nick kanala giren $+($(,,$+(%,#,join)),.) kişisin vs.
}

L4roXyL 11 Ekim 2011 01:57
Tarih: 27-05-2011, 21:21

Bu kod mIRC-de gönderdiğiniz text-lerin baş harflerini büyük yapmak için kullanılır. Yani bir nevi düzenli cümle gibi.

Kod:
on *:input:*:{
  if ($1 != $target && $1 !ison $target && $left($1,1) != /) {
    say $regsubex($1-,(^.),$upper($replace(\1,i,İ,ı,I)))
    haltdef
  }
}

L4roXyL 11 Ekim 2011 02:01
Tarih: 28-06-2011, 22:32

Bu kod herhangi bir kanalda rumuzunuzu yazan kullanıcıya sozler.txt -den bir texti/satırı notice olarak göndermenize olanak sağlar. Aynı nick için 10 saniye tekrar süresi vardır ve bu süreyi -mu10 kısmından bu süreyi değiştirebilirsiniz.

Kod:
on *:text:$($+(*,$me,*)):#: {
  hinc -mu10 _sz $nick 1
  $iif(!$fopen(_sz),.fopen _sz sozler.txt)
  $iif($feof,.fseek -l _sz 1)
  if ($hget(_sz,$nick) < 2) notice $nick $fread(_sz)
}

L4roXyL 11 Ekim 2011 23:08
Bu kodlar, farklı platformlarda mIRC Scripting bölümlerinde verdiğim yardımlardan size lazım olabilecek hazır kod/snippet niteliği taşıyan kodlardır.

Not: Tüm kodlar ilgili kişiler(yardım isteyen kişiler) tarafından denenmiş ve onaylanmıştır.
Not 2: Bu kodlar daha kısa ve işlevsel yazılabilir di, lakin gereksinime uygun ve anlayabileceğiniz açıklıkta yazılmıştır.

High 15 Şubat 2021 00:40
Alıntı:
L4roXyL Nickli Üyeden Alıntı (Mesaj 1242)
Tarih: 06-01-2008, 19:44

Kanal belirlediğiniz flood saldırısında, kanalı belirlediğiniz süre ile +m moduna alıp, temizle.mrc dosyasındaki verilerle kanalı temizleyip tekrar kanalaı açmak için yazmış olduğum bir kod.

Kod:
alias -l fld {
  hinc $+(-mu,$1) fld $+($3,½,$4,$encode($5)) 1
  if ($hget(fld,$+($3,½,$4,$encode($5))) >= $2) return $true
  else return $false
}
alias temizle {
  var %t 1
  while %t <= $lines(temizle.mrc) {
    msg $1 $read(temizle.mrc,%t)
    inc %t
  }
}
on @*:text:*:#: {
  if $nick isreg # && $fld(10,3,#,$nick,$1-) {
    ban -k # $nick 2 sebeb.
    mode # +m
    temizle #
    msg # Kanal güvenlik amaçlı 20 sn vs.
    if !$timer($+(#,½,fld)) {
      $+(.timer,½,#) 1 20 mode # -m
      .timer 1 21 msg # Kanal açıldı.
    }
  }
}
/fld alias'ının kullanımı; $fld(saniye,limit,#kanal,text-own,mesaj)
Ben örnek olarak; 10 saniye içerisin'de, aynı text 3 defa tekrar edilirse, gördüğünüz işlevleri sırası ile gerçekleştirir.

Eğer aynı yazının tekrar'ı değilde, belirlediğim saniye içerisin'de belirlediğim satır limit'i aşılırsa(hızlı text) işlev yapmak istiyorum diyorsan;
/fld alias'ını aşşağıdaki şekilde değiştir;

Kod:
alias -l fld {
 hinc $+(-mu,$1) fld $+($3,½,$4) 1
 if ($hget(fld,$+($3,½,$4)) >= $2) return $true
 else return $false
}


Ve kullanım şeklini verdiğim şekilde yap; $fld(saniye,limit,#kanal,text-own)

Örneğin; $fld(10,5,#,$nick)
10 saniye içerisinde, 5 satır text gönderen'e işlev yapar. Kanal'ı temizler vs.
Hocam izah ettiğiniz şekilde gerekli düzenlemeleri yaptım fakat KOD'u çalıştıramadım müsait olursan bi bakar mısın.

HTML-Kodu:
alias -l fld {
 hinc $+(-mu,$1) fld $+($3,½,$4) 1
 if ($hget(fld,$+($3,½,$4)) >= $2) return $true
 else return $false
}
on @*:text:*:#: {
  if $nick isreg # && $fld(2,8,#,$nick,$1-) {
    ban -k # $nick 4TXT Flood!10 Yaptığınız için kanaldan uzaklaştırıldınız.
    mode # +M
    .temizle #
    msg # 10Kanal da4 Txt flood10 tespit edildiği için4 Güvenlik amaçlı 1 dk Şifresiz nicklere10 kapatılmıştır.
    if !$timer($+(#,½,fld)) {
      $+(.timer,½,#) 1 60 mode # -M
      .timer 1 11 msg # 10Kanal geneli4 Şifresiz10 nicklere açılmıştır.4 İyi sohbetler
    }
  }
}


++ mIRCScripting.net hakkında kısaca:

mS; "Gayri resmi mIRC" kullanıcı ve tasarımcı topluluğudur.
2009 yılında kurulan mS; tasarımcı ve geliştiricileri bir araya getiren etkileşim ve iletişim sağlayan bir platformdur.
mS; tasarım, programlama, geliştirme, düzenleme vb. pek çok konu etrafında bir araya gelmiş "mIRC" meraklısı bir çok insan tarafından yaratılan içeriğiyle; kullanıcı dostu, özgün elit, nitelikli kişi ve konularla hizmet sunan mIRC Scripting platformudur.

Özgün içerikten onay almaksızın içeriği yaratan kullanıcılarımız tamamen yada kısmen sorumludur, aynı zamanda söz konusu içerik mS yetkilileri izni olmaksızın, kaynak gösterilse dahi(!) kopyalanamaz ve/ya paylaşılamaz.   Site/içerik hakkında görüş, öneri ve şikayetleriniz için sikayet[at]mircscripting[dot]net e-posta ve ya İletişim adresinden bizlere ulaştırabilirsiniz.



mIRC mIRC Orjinal mIRC İndir mIRC Download mIRC Tutorials mIRC Socket mIRC Commands mIRC Komutlar mIRC Yükle mIRC Dersler mIRC Hazır Kodlar mIRC Classentifier mIRC DLL mIRC Dialog mIRC IRC mIRC FTP mIRC Telnet mIRC Help
mIRC Yardım mIRC Iconlar mIRC Com Object mIRC Binary Files mIRC Picture Windows mIRC Unicode mIRC Forum mIRC Hazır Kodlar mIRC Kod mIRC Script mIRC File Handling mIRC Scripting Language mIRC Scripting Dili mIRC Scripting Info
mIRC Scripting Tutorials

Sayfa 3 Toplam 3 Sayfadan 12 3
Konuya ait 40 Mesajı başka Sayfada göster



User Alert System provided by Advanced User Tagging v3.1.3 (Lite) - vBulletin Mods & Addons Copyright © 2026 DragonByte Technologies Ltd. Runs best on HiVelocity Hosting.

1 2 13 14 16 17 18 19 21 22 23 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 49 50 51 52 54 55 56 57 58 59 60 61 62 63 67 68 69 70 71 72 73 74 75 76

SEO by vBSEO 3.6.1